forum.opsi.org

Guten Tag zusammen!

Ich versuche mich z.Z. daran, die originale install.wim (aus dem Ordner sources der Windows 7 DVD) anzupassen.
Ich wollte darin einige Windows Updates mit Hilfe einer Anleitung zum Einbinden von W-Updates implementieren.
Stichpunkte zur Einbindung (als Hilfe): dism, glb Ordner von WSUS Offline, /add-package

DIe Einbindung hat soweit ganz gut funktioniert.
Habe dann den gesamten Ordner sources incl der angepassten install.wim in den Ordner installfiles auf dem OPSI kopiert.
--set-rights ausgeführt

Die Installation scheint zu laufen - jedenfalls bis kurz vorm Ende.
Im Hintergrund sieht man das Windows-Installationsfenster am letzten Punkt, im Vordergrund (sinngemäß): Einige Komponenten konnten nicht richtig konfiguriert werden, Installation muss neu gestartet werden.
Eine Fehlermeldung von der Windows Installation.

Kennt hier jemand dieses Problem?

LG

Hallo,

mit dism hatte ich auch immerwieder Probleme.

Zum Patchen der DVD kann ich folgendes empfehlen: http://technet.microsoft.com/de-de/libr ... 10%29.aspx
Ist zwar aufwendiger aber es funktioniert.

Torsten

also ich habe auch updates mit DISM in meine WIM integriert. Hab damit bisher noch nie Probleme gehabt.
Ich würde es einfach nochmals probieren - eventuell verursacht ein Update Probleme bei der Installation?

Am ende is das integrieren mit DISM aber eh nur eine minimale Zeitersparnis gegenüber einem richtigen Script als Paket.
Im WIKI sind mehrere Script-Varianten für die Updates die automatisch laden und installieren können.
Ich denke da ist auch ein geeignetes für dich dabei

Moin zusammen,

Ich habe mich die Tage auch mit dem Aktualisieren des wim-Files beschäftigt.
Die Fehlermeldung kann ich bestätigen, hatte sie gestern auch.

Werde mal den Link von hoscht13 ausprobieren.

djspcworld hat geschrieben:Guten Tag zusammen!

Ich versuche mich z.Z. daran, die originale install.wim (aus dem Ordner sources der Windows 7 DVD) anzupassen.
Ich wollte darin einige Windows Updates mit Hilfe einer Anleitung zum Einbinden von W-Updates implementieren.
Stichpunkte zur Einbindung (als Hilfe): dism, glb Ordner von WSUS Offline, /add-package

DIe Einbindung hat soweit ganz gut funktioniert.
Habe dann den gesamten Ordner sources incl der angepassten install.wim in den Ordner installfiles auf dem OPSI kopiert.
--set-rights ausgeführt

Die Installation scheint zu laufen - jedenfalls bis kurz vorm Ende.
Im Hintergrund sieht man das Windows-Installationsfenster am letzten Punkt, im Vordergrund (sinngemäß): Einige Komponenten konnten nicht richtig konfiguriert werden, Installation muss neu gestartet werden.
Eine Fehlermeldung von der Windows Installation.

Kennt hier jemand dieses Problem?

LG

Okay,

ich habe eine Methode gefunden die funktioniert.
Sie reduziert die gefundenen Updates nach der Installation von 106 auf 26.

Dazu wie folgt vorgehen:
Im Prinzip dieser Anleitung hier folgen,
http://www.wiegehtdas.ch/how-to/windows ... grieren-2/

nur mit dem Unterschied dass die Updates mit dem com! Update-Pack-Builder geladen werden.

-> com! Update-Pack-Builder installieren
- Neues Projekt
- Updates nicht in CD integrieren
- Windows 7 x64 mit SP1 auswählen - [für andere Versionen nicht getestet]
- Alle Updates bis auf Net-Framework und Internet Explorer auswählen und herunterladen lassen
- Updatepack erstellen lassen

- Das Updatepack wieder extrahieren und den Ordner mit den Updates wie in der Anleitung oben
beschrieben in das install.wim integrieren.

Die WIndows-Installation läuft ohne Fehler durch.
Danach müssen nur noch 26 Updates über Windows Update nachinstalliert werden.

Feedback ob es mit anderen Versionen auch funktioniert ist natürlich willkommen!

Viele Grüße und viel Erfolg.
[ SilenceWithin ]

Mit der Anleitung von http://www.wiegehtdas.ch/how-to/windows ... grieren-2/ kam ich genauso nicht weiter.
Scheinbar kommt vom WSUS-Offline irgendein Update, welches sich nicht mit dem Windows Setup verträgt.

Der Vorteil die Updates mittels Sysprep in die install.wim zu integrieren, ist weitere Einstellungen und Verknüpfungen anpassen zu können (z.B. ODBC-Verwaltung 32 Bit).
Nachteilig ist die Größe der install.wim ist dabei entsteht. Meine ist schon fast 4GB groß (trotz /compress:maximum).

Torsten

Ich habe hier mal ein Tutorial geschrieben, mit dessen Hilfe man
die Installationsdvd weitesgehend automatisch aktualisieren lassen
kann. Die Aktualisierung wurde hier auf einem 64 Bit Windows 7 Pro
ausgeführt. Vielleicht ist es ja für den einen oder anderen hilfreich!

Anstoß für dieses Projekt:
---------------------------
Das Ziel bestand darin die Installations-Images von Win 7 auf dem Opsiserver möglichst aktuell zu haben
http://www.wiegehtdas.ch/how-to/windows ... grieren-2/

Was gebraucht wird:
--------------------
-> Windows Assessment and Deployment Kit (ADK) für Windows® 8 http://www.microsoft.com/de-DE/download ... x?id=30652
-> com Update Pack Builder http://www.com-magazin.de/downloads/com ... 70179.html
-> ISO von Windows 7 SP 1 32 Bit http://msft.digitalrivercontent.net/win/X17-59886.iso
-> ISO von Windows 7 SP 1 64 Bit http://msft.digitalrivercontent.net/win/X17-59885.iso
-> plink.exe http://the.earth.li/~sgtatham/putty/lat ... /plink.exe

Die Vorbereitungen:
---------------------
-> Windows ADK für Windows 8 installieren. hier aber nur die BereitstellungsTools
-> com! Update-Pack-Builder installieren
- Neues Projekt
- Updates nicht in CD integrieren
- Windows 7 x64 mit SP1 / Windows 7 x86 mit SP1auswählen
- Alle Updates bis auf Net-Framework und Internet Explorer auswählen und herunterladen lassen
- Updatepack erstellen lassen
- Das Updatepack wieder extrahieren und den Ordner mit den Updates [Data] als Ordner Patches 64Bit / 32Bit-Ordner ablegen
-> Das jeweilige ISO von Windows 7 SP1 herunterladen und in den gleichnamigen Ordner entpacken
-> plink herunterladen und im "<ARC>" Ordner speichern

Updates integrieren:
---------------------
- Update_wim.cmd im Editor öffnen und u.U. noch die Pfade /Variablen anpassen [Zeilen 27 bis 40]
- Verknüpfung "Update integrieren" erstellen mit C:\Windows\System32\cmd.exe /k "E:\Microsoft Windows 7 Professional\64Bit\Update_wim.cmd"
- "Update integrieren" als Admin ausführen, Verarbeitungsoptionen setzen und nen Kaffee trinken gehen.
- Überall die Pfade entsprechend anpassen

Anmerkungen:
-------------
- Um eine koplette DVD zu aktualisieren, müssen alle Editionen auf diese Art aktualisiert werden, erst danach sollte die DVD erstellt werden.
- Die Batch enthält eine Routine die die neuen Installationsdateién automatisch auf den Opsiserver kopiert und die entsprechenden Verzeichnisrechte setzt.
- Die Installationen wurden getestet und funktionieren
- Nach abgeschlossener Installation müssen nur noch ca. 26 Updates installiert werden, zuvor waren es 106

- Das System kann nach Fertigstellung aller Aufgaben heruntergefahren werden

Update_wim.cmd für 32 Bit

Code: Alles auswählen

@Echo off
:: Hintergrund weiß, Vordergrund blau
color F1
echo Updating path to include dism, oscdimg, imagex
echo.
echo    %~dp0

if /i %PROCESSOR_ARCHITECTURE% EQU X86 echo    %~dp0..\%PROCESSOR_ARCHITECTURE%
if /i %PROCESSOR_ARCHITECTURE% NEQ X86 echo    %~dp0..\%PROCESSOR_ARCHITECTURE%;%~dp0..\x86

if /i %PROCESSOR_ARCHITECTURE% EQU X86 echo    %~dp0..\%PROCESSOR_ARCHITECTURE%\Servicing;
if /i %PROCESSOR_ARCHITECTURE% NEQ X86 echo    %~dp0..\%PROCESSOR_ARCHITECTURE%\Servicing;%~dp0..\x86\Servicing;

echo.
if /i %PROCESSOR_ARCHITECTURE% EQU X86 set PATH=%~dp0;%~dp0..\%PROCESSOR_ARCHITECTURE%;%~dp0..\%PROCESSOR_ARCHITECTURE%\Servicing;%PATH%;
if /i %PROCESSOR_ARCHITECTURE% NEQ X86 set PATH=%~dp0;%~dp0..\%PROCESSOR_ARCHITECTURE%;%~dp0..\x86;%~dp0..\%PROCESSOR_ARCHITECTURE%\Servicing;%~dp0..\x86\Servicing;%PATH%;
cd /d %~dp0
cls

:: dism /get-wiminfo /wimfile:"E:\Microsoft Windows 7 Professional\32Bit\Win7_ALL_SP1_ger_x86_X17-59886\sources\install.wim"
echo.
echo.
echo _______________________________________
echo   Lese Variablen ein ...
echo.
:: Die folgenden Variablen anpassen
Set DVD_Content_Root_Folder=E:\Microsoft Windows 7 Professional\32Bit\Win7_ALL_SP1_ger_x86_X17-59886
Set WimFile="%DVD_Content_Root_Folder%\sources\install.wim"
Set ISO_BootFile="%DVD_Content_Root_Folder%\boot\etfsboot.com"
Set ISO_Output_Path="%DVD_Content_Root_Folder%_u.iso"
Set Opsi_win7x86_installfiles_Folder="\\opsiserver\opt_pcbin\install\win7\installfiles"
Set MountDirFolder=C:\wimmount

:: Der Ordner mit den Updates vom "com! Update Pack Builder" 
Set PackagepathFolder=E:\Microsoft Windows 7 Professional\32Bit\patches

:: Opsiserver Zugangsdaten
Set Opsiserver_IP=XXX.XXX.XXX.XXX
Set Opsiserver_User=root
Set Opsiserver_Uspw=deinpasswort
echo DONE!
echo. 

:SetupSettings
cls
:: _____________________________________________________________________________________________________________________
:: Einstellungen abfragen
:: _____________________________________________________________________________________________________________________
echo. 
echo Folgende Standardeinstellungen sind gesetzt:
echo. 
echo Windowsversion: Windows 7 SP 1 x86 Professional
echo Image aktualisieren: J
echo Daten auf Opsiserver aktualisieren: J
echo Verzeichnisrechte auf Opsiserver setzen; J
echo Details ausblenden: J
echo Neue DVD erstellen: J
echo System Herunterfahren: N
echo. 

Set /P Settings= Sollen diese Einstellungen verwendet werden? Ja=1 Nein=0: 
if /I "%Settings%"=="1" goto :Presets
if /I "%Settings%"=="0" goto :CustumSets 


:CustumSets
cls
:: Auswahl der Windows Version
echo. 
echo 1 = Windows 7 SP 1 x86 Starter
echo 2 = Windows 7 SP 1 x86 HomeBasic
echo 3 = Windows 7 SP 1 x86 HomePremium
echo 4 = Windows 7 SP 1 x86 Professional
echo 5 = Windows 7 SP 1 x86 Ultimate
echo.
Set /P Version_index= Welche Edition soll aktualisiert werden? [1,2,3,4,5]: 
:: Update WIM-Image
Set /P Update_wimimage= Soll das Image aktualisiert werden? Ja=1 Nein=0: 
:: Update Opsiserver Files
Set /P Update_Opsiserver_Files= Daten auf Opsiserver aktualisieren? Ja=1 Nein=0: 
:: Schaltet die Statusanzeige bim Loeschen und Kopieren ein/aus
Set /P Quiet_Switch= Details waehrend der Verarbeitung ausblenden? Ja=1 Nein=0: 
:: Steuert das Update der Verzeicnisrechte auf dem Opsiserver
Set /P Update_Folder_Rights= Verzeichnisrechte auf Opsiserver setzen? Ja=1 Nein=0: 
:: Der folgende Schalter steuert die Erstellung des DVD Images
Set /P Create_DVD_Image= Neue DVD erstellen? Ja=1 Nein=0: 
:: Soll das System heruntergefahren werden?
Set /P Shut_System_Down= Soll das System heruntergefahren werden? Ja=1 Nein=0: 

cls
echo.
echo Folgende Einstellungen wurden gesetzt:
echo. 
echo Windowsversion: %Version_index%
echo Image aktualisieren: %Update_wimimage%
echo Daten auf Opsiserver aktualisieren: %Update_Opsiserver_Files%
echo Verzeichnisrechte auf Opsiserver setzen; %Update_Folder_Rights%
echo Details ausblenden: %Quiet_Switch%
echo Neue DVD erstellen: %Create_DVD_Image%
echo System Herunterfahren: %Shut_System_Down%
echo. 

Set /P Settings= Sollen diese Einstellungen verwendet werden? Ja=1 Nein=0: 
if /I "%Settings%"=="1" goto :LetsRock
if /I "%Settings%"=="0" goto ::SetupSettings 

:Presets
:: _____________________________________________________________________________________________________________________
:: Steuert die auszuführenden Operationen
:: _____________________________________________________________________________________________________________________

:: Auswahl der Windows Version
Set Version_index=4
:: 1 = Windows 7 SP 1 x86 Starter
:: 2 = Windows 7 SP 1 x86 HomeBasic
:: 3 = Windows 7 SP 1 x86 HomePremium
:: 4 = Windows 7 SP 1 x86 Professional
:: 5 = Windows 7 SP 1 x86 Ultimate

:: Update WIM-Image
Set Update_wimimage=1

:: Update Opsiserver Files
Set Update_Opsiserver_Files=1
:: Schaltet die Statusanzeige bim Loeschen und Kopieren ein/aus
Set Quiet_Switch=1
:: Steuert das Update der Verzeicnisrechte auf dem Opsiserver
Set Update_Folder_Rights=1

:: Der folgende Schalter steuert die Erstellung des DVD Images
Set Create_DVD_Image=1

:: System herunterfahren
Set Shut_System_Down=0

:LetsRock
:: _____________________________________________________________________________________________________________________
:: Zuweisen der Optionen / Parameter
:: _____________________________________________________________________________________________________________________

:: Zuweisen des OS Versionsstrings
if %Version_index%'==1' (
	Set Current_OS_Version="Windows 7 SP 1 x86 Starter"
)
if %Version_index%'==2' (
	Set Current_OS_Version="Windows 7 SP 1 x86 HomeBasic"
)
if %Version_index%'==3' (
	Set Current_OS_Version="Windows 7 SP 1 x86 HomePremium"
)
if %Version_index%'==4' (
	Set Current_OS_Version="Windows 7 SP 1 x86 Professional"
)
if %Version_index%'==5' (
	Set Current_OS_Version="Windows 7 SP 1 x86 Ultimate"
)

:: Schaltet die Statusanzeige bim Loeschen und Kopieren ein/aus
if %Quiet_Switch%'==1' (
	Set Quiet_Switch_param=/Q
) else (
	Set Quiet_Switch_param=
)
:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

:: Anlegen des Mounteverzeichnisses wenn es nicht existiert
echo.
echo.
echo _______________________________________
echo   Erstelle Mount-Verzeichnis
echo   %MountDirFolder%
echo.
echo ...
if not exist "%MountDirFolder%" mkdir "%MountDirFolder%"
echo DONE!

:: Löschen von Updates die Fehler hervorrufen oder nicht integriert werden können
echo.
echo.
echo _______________________________________
echo   Bereinige "Patches"-Verzeichnis
echo   %PackagepathFolder%
echo.
echo ...
if exist "%PackagepathFolder%\Windows-KB890830-x86-V4.20.exe" del "%PackagepathFolder%\Windows-KB890830-x86-V4.20.exe"
if exist "%PackagepathFolder%\wizardimage.bmp" del "%PackagepathFolder%\wizardimage.bmp"
if exist "%PackagepathFolder%\Icon.ico" del "%PackagepathFolder%\Icon.ico"
if exist "%PackagepathFolder%\Language.ini" del "%PackagepathFolder%\Language.ini"
if exist "%PackagepathFolder%\Settings.ini" del "%PackagepathFolder%\Settings.ini"
echo DONE!

:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

:: In diesem Vorgang wird das Image aktualisiert
if %Update_wimimage%'==1' (
	echo ______________________________________________________
	echo Zur Vermeidung von Fehlern waehrend der Verarbeitung
	echo sollten alle Explorer-Fenster geschlossen werden!
	echo. 
	pause

	:: WIM-Datei laden
	echo.
	echo.
	echo _______________________________________
	echo  %Current_OS_Version%
	echo   haenge die WIM-Datei ein ...
	echo.
	echo ...
	dism /mount-wim /wimfile:%WimFile% /index:%Version_index% /mountdir:"%MountDirFolder%"
	echo DONE!

	:: Integriere Updates
	echo.
	echo.
	echo _______________________________________
	echo.  %Current_OS_Version%
	echo   integriere Updates...
	echo.
	echo ...
	dism /image:"%MountDirFolder%" /add-package /packagepath:"%PackagepathFolder%"
	echo DONE!

	:: WIM-Datei speichern und aushängen
	echo.
	echo.
	echo _______________________________________
	echo.  %Current_OS_Version%
	echo   haenge die WIM-Datei aus ...
	echo.
	echo ...
	dism /unmount-wim /mountdir:"%MountDirFolder%" /commit
	echo DONE!
)
:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

if %Update_Opsiserver_Files%'==1' (
	:: Löschen der Daten auf dem Opsiserver
	echo.
	echo.
	echo _______________________________________
	echo   Loesche Daten auf dem Opsiserver
	echo   %Opsi_win7x86_installfiles_Folder%
	echo.
	echo ...
	if exist %Opsi_win7x86_installfiles_Folder% rmdir %Opsi_win7x86_installfiles_Folder% /S %Quiet_Switch_param%
	echo DONE!

	:: Kopieren der neuen Daten
	echo.
	echo.
	echo _______________________________________
	echo   Kopiere Daten auf den Opsiserver
	echo   %Opsi_win7x86_installfiles_Folder%
	echo.
	echo ...
	xcopy "%DVD_Content_Root_Folder%" "%Opsi_win7x86_installfiles_Folder%\" /Y /E %Quiet_Switch_param%
	echo DONE!
)
:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

:: Setze Verzeichnisrechte auf dem Opsiserver
if %Update_Folder_Rights%'==1' (
	echo.
	echo.
	echo _______________________________________
	echo   Setze Verzeichnisrechte auf dem Opsiserver fuer Verzeichnis 
	echo   %Opsi_win7x86_installfiles_Folder%
	echo.
	echo ...
	plink.exe %Opsiserver_User%@%Opsiserver_IP% -pw %Opsiserver_Uspw% "opsi-setup --set-rights /opt/pcbin/install/win7/installfiles"
	echo DONE!
)
:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

:: Neues CD-Image anlegen
if %Create_DVD_Image%'==1' (
	echo.
	echo.
	echo _______________________________________
	echo   Erstelle neues DVD-Image
	echo.
	echo ...
	"%ProgramFiles%\Windows AIK\Tools\amd64\oscdimg.exe" -lWIN7 -m -u2 -b%ISO_BootFile% "%DVD_Content_Root_Folder%" %ISO_Output_Path%
	echo DONE!
)
:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

:: Löschen des Mounteverzeichnisses
echo.
echo.
echo _______________________________________
echo   Loesche das Mountverzeichnis
echo.
echo ...
rmdir "%MountDirFolder%"
echo DONE!

:: System herunterfahren
if %Shut_System_Down%'==1' (
	echo.
	echo.
	echo _______________________________________
	echo   PC wird heruntergefahren
	echo.
	echo ...
	shutdown /s /t 180
	echo DONE!
)
:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

:: der Vorgang ist abgeschlossen
echo.
echo.
echo ----------------------------------------------------
echo   Die Verarbeitung aller Aufgaben ist abgeschlossen
echo ----------------------------------------------------
echo. 
pause
cls
goto :SetupSettings

Update_wim.cmd für 64 Bit

Code: Alles auswählen

@Echo off
:: Hintergrund weiß, Vordergrund blau
color F1
echo Updating path to include dism, oscdimg, imagex
echo.
echo    %~dp0

if /i %PROCESSOR_ARCHITECTURE% EQU X86 echo    %~dp0..\%PROCESSOR_ARCHITECTURE%
if /i %PROCESSOR_ARCHITECTURE% NEQ X86 echo    %~dp0..\%PROCESSOR_ARCHITECTURE%;%~dp0..\x86

if /i %PROCESSOR_ARCHITECTURE% EQU X86 echo    %~dp0..\%PROCESSOR_ARCHITECTURE%\Servicing;
if /i %PROCESSOR_ARCHITECTURE% NEQ X86 echo    %~dp0..\%PROCESSOR_ARCHITECTURE%\Servicing;%~dp0..\x86\Servicing;

echo.
if /i %PROCESSOR_ARCHITECTURE% EQU X86 set PATH=%~dp0;%~dp0..\%PROCESSOR_ARCHITECTURE%;%~dp0..\%PROCESSOR_ARCHITECTURE%\Servicing;%PATH%;
if /i %PROCESSOR_ARCHITECTURE% NEQ X86 set PATH=%~dp0;%~dp0..\%PROCESSOR_ARCHITECTURE%;%~dp0..\x86;%~dp0..\%PROCESSOR_ARCHITECTURE%\Servicing;%~dp0..\x86\Servicing;%PATH%;
cd /d %~dp0
cls
echo.
echo.
echo _______________________________________
echo   Lese Variablen ein ...
echo.
:: Die folgenden Variablen anpassen
Set DVD_Content_Root_Folder=E:\Microsoft Windows 7 Professional\64Bit\Win7_ALL_SP1_ger_x64_X17-59885
Set WimFile="%DVD_Content_Root_Folder%\sources\install.wim"
Set ISO_BootFile="%DVD_Content_Root_Folder%\boot\etfsboot.com"
Set ISO_Output_Path="%DVD_Content_Root_Folder%_u.iso"
Set Opsi_win7x64_installfiles_Folder="\\opsiserver\opt_pcbin\install\win7-x64\installfiles"
Set MountDirFolder=C:\wimmount

:: Der Ordner mit den Updates vom "com! Update Pack Builder" 
Set PackagepathFolder=E:\Microsoft Windows 7 Professional\64Bit\patches

:: Opsiserver Zugangsdaten
Set Opsiserver_IP=XXX.XXX.XXX.XXX
Set Opsiserver_User=root
Set Opsiserver_Uspw=deinpasswort
echo DONE!
echo. 

:SetupSettings
cls
:: _____________________________________________________________________________________________________________________
:: Einstellungen abfragen
:: _____________________________________________________________________________________________________________________
echo. 
echo Folgende Standardeinstellungen sind gesetzt:
echo. 
echo Windowsversion: Windows 7 SP 1 x64 Professional
echo Image aktualisieren: J
echo Daten auf Opsiserver aktualisieren: J
echo Verzeichnisrechte auf Opsiserver setzen; J
echo Details ausblenden: J
echo Neue DVD erstellen: J
echo System Herunterfahren: N
echo. 

Set /P Settings= Sollen diese Einstellungen verwendet werden? Ja=1 Nein=0: 
if /I "%Settings%"=="1" goto :Presets
if /I "%Settings%"=="0" goto :CustumSets 


:CustumSets
cls
:: Auswahl der Windows Version
echo. 
echo 1 = Windows 7 SP 1 x64 HomeBasic
echo 2 = Windows 7 SP 1 x64 HomePremium
echo 3 = Windows 7 SP 1 x64 Professional
echo 4 = Windows 7 SP 1 x64 Ultimate
echo.
Set /P Version_index= Welche Edition soll aktualisiert werden? [1,2,3,4]: 
:: Update WIM-Image
Set /P Update_wimimage= Soll das Image aktualisiert werden? Ja=1 Nein=0: 
:: Update Opsiserver Files
Set /P Update_Opsiserver_Files= Daten auf Opsiserver aktualisieren? Ja=1 Nein=0: 
:: Schaltet die Statusanzeige bim Loeschen und Kopieren ein/aus
Set /P Quiet_Switch= Details waehrend der Verarbeitung ausblenden? Ja=1 Nein=0: 
:: Steuert das Update der Verzeicnisrechte auf dem Opsiserver
Set /P Update_Folder_Rights= Verzeichnisrechte auf Opsiserver setzen? Ja=1 Nein=0: 
:: Der folgende Schalter steuert die Erstellung des DVD Images
Set /P Create_DVD_Image= Neue DVD erstellen? Ja=1 Nein=0: 
:: Soll das System heruntergefahren werden?
Set /P Shut_System_Down= Soll das System heruntergefahren werden? Ja=1 Nein=0: 

cls
echo.
echo Folgende Einstellungen wurden gesetzt:
echo. 
echo Windowsversion: %Version_index%
echo Image aktualisieren: %Update_wimimage%
echo Daten auf Opsiserver aktualisieren: %Update_Opsiserver_Files%
echo Verzeichnisrechte auf Opsiserver setzen; %Update_Folder_Rights%
echo Details ausblenden: %Quiet_Switch%
echo Neue DVD erstellen: %Create_DVD_Image%
echo System Herunterfahren: %Shut_System_Down%
echo. 

Set /P Settings= Sollen diese Einstellungen verwendet werden? Ja=1 Nein=0: 
if /I "%Settings%"=="1" goto :LetsRock
if /I "%Settings%"=="0" goto ::SetupSettings 

:Presets
:: _____________________________________________________________________________________________________________________
:: Steuert die auszuführenden Operationen
:: _____________________________________________________________________________________________________________________

:: Auswahl der Windows Version
Set Version_index=3
:: 1 = Windows 7 SP 1 x64 HomeBasic
:: 2 = Windows 7 SP 1 x64 HomePremium
:: 3 = Windows 7 SP 1 x64 Professional
:: 4 = Windows 7 SP 1 x64 Ultimate

:: Update WIM-Image
Set Update_wimimage=1

:: Update Opsiserver Files
Set Update_Opsiserver_Files=1
:: Schaltet die Statusanzeige bim Loeschen und Kopieren ein/aus
Set Quiet_Switch=1
:: Steuert das Update der Verzeicnisrechte auf dem Opsiserver
Set Update_Folder_Rights=1

:: Der folgende Schalter steuert die Erstellung des DVD Images
Set Create_DVD_Image=1

:: System herunterfahren
Set Shut_System_Down=0

:LetsRock
:: _____________________________________________________________________________________________________________________
:: Zuweisen der Optionen / Parameter
:: _____________________________________________________________________________________________________________________

:: Zuweisen des OS Versionsstrings
if %Version_index%'==1' (
	Set Current_OS_Version="Windows 7 SP 1 x64 HomeBasic"
)
if %Version_index%'==2' (
	Set Current_OS_Version="Windows 7 SP 1 x64 HomePremium"
)
if %Version_index%'==3' (
	Set Current_OS_Version="Windows 7 SP 1 x64 Professional"
)
if %Version_index%'==4' (
	Set Current_OS_Version="Windows 7 SP 1 x64 Ultimate"
)

:: Schaltet die Statusanzeige bim Loeschen und Kopieren ein/aus
if %Quiet_Switch%'==1' (
	Set Quiet_Switch_param=/Q
) else (
	Set Quiet_Switch_param=
)
:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

:: Anlegen des Mounteverzeichnisses wenn es nicht existiert
echo.
echo.
echo _______________________________________
echo   Erstelle Mount-Verzeichnis
echo   %MountDirFolder%
echo.
echo ...
if not exist "%MountDirFolder%" mkdir "%MountDirFolder%"
echo DONE!

:: Löschen von Updates die Fehler hervorrufen oder nicht integriert werden können
echo.
echo.
echo _______________________________________
echo   Bereinige "Patches"-Verzeichnis
echo   %PackagepathFolder%
echo.
echo ...
if exist "%PackagepathFolder%\Windows-KB890830-x64-V4.20.exe" del "%PackagepathFolder%\Windows-KB890830-x64-V4.20.exe"
if exist "%PackagepathFolder%\wizardimage.bmp" del "%PackagepathFolder%\wizardimage.bmp"
if exist "%PackagepathFolder%\Icon.ico" del "%PackagepathFolder%\Icon.ico"
if exist "%PackagepathFolder%\Language.ini" del "%PackagepathFolder%\Language.ini"
if exist "%PackagepathFolder%\Settings.ini" del "%PackagepathFolder%\Settings.ini"
echo DONE!

:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

:: In diesem Vorgang wird das Image aktualisiert
if %Update_wimimage%'==1' (
	echo ______________________________________________________
	echo Zur Vermeidung von Fehlern waehrend der Verarbeitung
	echo sollten alle Explorer-Fenster geschlossen werden!
	echo. 
	pause

	:: WIM-Datei laden
	echo.
	echo.
	echo _______________________________________
	echo  %Current_OS_Version%
	echo   haenge die WIM-Datei ein ...
	echo.
	echo ...
	dism /mount-wim /wimfile:%WimFile% /index:%Version_index% /mountdir:"%MountDirFolder%"
	echo DONE!

	:: Integriere Updates
	echo.
	echo.
	echo _______________________________________
	echo.  %Current_OS_Version%
	echo   integriere Updates...
	echo.
	echo ...
	dism /image:"%MountDirFolder%" /add-package /packagepath:"%PackagepathFolder%"
	echo DONE!

	:: WIM-Datei speichern und aushängen
	echo.
	echo.
	echo _______________________________________
	echo.  %Current_OS_Version%
	echo   haenge die WIM-Datei aus ...
	echo.
	echo ...
	dism /unmount-wim /mountdir:"%MountDirFolder%" /commit
	echo DONE!
)
:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

if %Update_Opsiserver_Files%'==1' (
	:: Löschen der Daten auf dem Opsiserver
	echo.
	echo.
	echo _______________________________________
	echo   Loesche Daten auf dem Opsiserver
	echo   %Opsi_win7x64_installfiles_Folder%
	echo.
	echo ...
	if exist %Opsi_win7x64_installfiles_Folder% rmdir %Opsi_win7x64_installfiles_Folder% /S %Quiet_Switch_param%
	echo DONE!

	:: Kopieren der neuen Daten
	echo.
	echo.
	echo _______________________________________
	echo   Kopiere Daten auf den Opsiserver
	echo   %Opsi_win7x64_installfiles_Folder%
	echo.
	echo ...
	xcopy "%DVD_Content_Root_Folder%" "%Opsi_win7x64_installfiles_Folder%\" /Y /E %Quiet_Switch_param%
	echo DONE!
)
:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

:: Setze Verzeichnisrechte auf dem Opsiserver
if %Update_Folder_Rights%'==1' (
	echo.
	echo.
	echo _______________________________________
	echo   Setze Verzeichnisrechte auf dem Opsiserver fuer Verzeichnis 
	echo   %Opsi_win7x64_installfiles_Folder%
	echo.
	echo ...
	plink.exe %Opsiserver_User%@%Opsiserver_IP% -pw %Opsiserver_Uspw% "opsi-setup --set-rights /opt/pcbin/install/win7-x64/installfiles"
	echo DONE!
)
:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

:: Neues CD-Image anlegen
if %Create_DVD_Image%'==1' (
	echo.
	echo.
	echo _______________________________________
	echo   Erstelle neues DVD-Image
	echo.
	echo ...
	"%ProgramFiles%\Windows AIK\Tools\amd64\oscdimg.exe" -lWIN7 -m -u2 -b%ISO_BootFile% "%DVD_Content_Root_Folder%" %ISO_Output_Path%
	echo DONE!
)
:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

:: Löschen des Mounteverzeichnisses
echo.
echo.
echo _______________________________________
echo   Loesche das Mountverzeichnis
echo.
echo ...
rmdir "%MountDirFolder%"
echo DONE!

:: System herunterfahren
if %Shut_System_Down%'==1' (
	echo.
	echo.
	echo _______________________________________
	echo   PC wird heruntergefahren
	echo.
	echo ...
	shutdown /s /t 180
	echo DONE!
)
:: _____________________________________________________________________________________________________________________
:: _____________________________________________________________________________________________________________________

:: der Vorgang ist abgeschlossen
echo.
echo.
echo ----------------------------------------------------
echo   Die Verarbeitung aller Aufgaben ist abgeschlossen
echo ----------------------------------------------------
echo. 
pause
cls
goto :SetupSettings

Wer will darf die Dateien gerne erweitern / verbessern.
Vielleicht kann man dann die verbesserte Version wieder
im Forum bereitstellen.

Viel Spaß

[ SilenceWithin ]

Verfasst: **03 Jun 2013, 10:29**

oder gerne auch im Wiki. Im Forum gehen solche Informationen mit der Zeit meistens unter.

Verfasst: **18 Jun 2013, 09:32**

Ich habe mal einen Eintrag vorbereitet. Da brauchst du die Anleitung nur noch reinkopieren.

wiki/userspace:windows_7_updates_integrieren

Gruß Karsten Köpke

Verfasst: **15 Aug 2013, 15:41**

@SilenceWithin

Hui.... das sieht ja toll aus! Vielen Dank!

Eine Frage: Warum sollen Updates für den IE nicht integriert werden? Gibt es hierfür einen speziellen Grund?

Grüße (und nochmals Danke...)

JMS

forum.opsi.org

Angepasste install.wim (WIndows 7)

Angepasste install.wim (WIndows 7)

Re: Angepasste install.wim (WIndows 7)

Re: Angepasste install.wim (WIndows 7)

Re: Angepasste install.wim (WIndows 7)

Re: Angepasste install.wim (WIndows 7)

Re: Angepasste install.wim (WIndows 7)

Re: Angepasste install.wim (WIndows 7)

Re: Angepasste install.wim (WIndows 7)

Re: Angepasste install.wim (WIndows 7)

Re: Angepasste install.wim (WIndows 7)