forum.opsi.org

Hallo,

hab das Handbuch durchsucht, aber leider nix passendes gefunden. Ebenso konnte ich bisher nichts passendes im Forum finden.

Ich habe ein ein OPSI Paket namens StandardProgramme dort habe ich über Abhängigkeiten alle benötigten Programme eingebunden. Nun meine Frage, kann ich irgendwie die Installationsreihenfolge der Pakete bestimmen, bzw. in welcher Reihenfolge werden die Pakete aufgerufen?

Danke und Gruß
Sven

ab Version 4.0 mit Prioritäten

im instlog steht die reihenfolge die er vom opsi-server bekommt, genau nach der reihenfolge werden sie dann installiert.

Hallo,

Prioritäten könntest du auch mit Abhängigkeiten realisieren.
Z.b. soll mozilla firefox installiert werden und dann kannst du mittels Abhängigkeit einstellen, dass z.b. das swaudit nachher installiert werden soll.
Da gibt es mehr Parameter... setup, update, after, before...

Grüße

Hallo.

Mach dir doch ein neues Paket mit einem Installations-Script, also z.B. "standard-liste.ins".
Kopierst das Script ins Verzeichnis "CLIENT_DATA" wie üblich ohne sonstige Files oder
Daten. Erstellst das Paket und Installierst es mit dem package-manager. Dieses Script
kannst du nachträglich immer wieder abändern. Ich habe das Script folgendermaßen aufgebaut:

Beispiel Installationsliste:

(Danach folgt ein Beispiel für die einzelnen Pakete) !!Wichtig!!

******************************************************************************************************************
[Initial]
Message=Installiere "Windows XP Standard Pakete"...
StayOnTop=false
LogLevel=2
ExitOnError=false
ScriptErrorMessages=on
TraceMode=off

;*******************************************************************************************************************************************
[Aktionen]
DefVar $OS$
DefVar $MinorOS$
DefVar $TypeOS$
DefVar $Flag$
DefVar $ExitCode$
DefVar $WinstRegKey$
DefVar $RebootRegVar$
Set $OS$ = GetOS
Set $MinorOS$ = GetNTVersion
Set $TypeOS$ = GetSystemType

if $OS$="Windows_NT"
Set $WinstRegKey$ = "HKLM\SOFTWARE\opsi.org\winst"
Set $Flag$ = GetRegistryStringValue ("["+$WinstRegKey$+"] "+"RebootFlag")
if not ($Flag$ > "")
Set $Flag$ = "1"
sub "P:\install\SPD-007-Haus-Schriften\ls-inst-schriften.ins"
sub "P:\install\SPD-010-MS-DotNet\ls-inst-dotnet.ins"
sub "P:\install\SPD-011-MS-DotNet\ls-inst-dotnet.ins"
Registry_SaveRebootFlag
ExitWindows /ImmediateReboot
endif
if not ($Flag$ > "1")
sub "P:\install\SPD-060-Sun-Java-Virtual\ls-inst-sun-java.ins"
sub "P:\install\SPD-061-Real-VNC-Server\ls-inst-real-vnc.ins"
sub "P:\install\SPD-062-Irfan-View\ls-inst-irfan-view.ins"
Set $Flag$ = "2"
Registry_SaveRebootFlag
ExitWindows /ImmediateReboot
endif
if $Flag$ = "2"
sub "P:\install\SPD-042-Open-Office-Writer\ls-inst-open-office.ins"
sub "P:\install\SPD-040-MS-Office-2003\ls-inst-ms-office-2003.ins"
sub "P:\install\SPD-041-MS-Office-Compatibility-2007\ls-inst-ms-comp-2007.ins"
Set $Flag$ = "0"
Registry_SaveRebootFlag
ExitWindows /Reboot
endif
endif

;*******************************************************************************************************************************************
[Registry_SaveRebootFlag]
openKey [$WinstRegKey$]
set "RebootFlag" = "$Flag$"
;********************************************************************************************************************************************

Manche Applikationen brauchen einen Reboot nach der Installation, den kannst du mit dem Reboot-Flag realisieren so wie
ich es im obigen Beispiel eingebaut habe.

Beispiel *.ins Script für die Software Pakete:

Hier ist wichtig das du hier keinen [Initial] und [Aktions] Bereich und keine Definitionen von Variablen einfügst!! Diese
Paket Installations Scripte sind dann SUB Scripte von der Installations-Liste. Du musst also zwei *.ins Scripte pro
Paket erstellen und die dementsprechend benennen. z.B. "solo-paket.ins" und "liste-paket.ins"

;********************************************************************************************************************************************
Message "Installiere Microsoft Internet Explorer 8"

WinBatch_Install

[WinBatch_Install]
P:\install\SPD-012-MS-IE8\files\IE8-WindowsXP-x86-DEU.exe /passive /update-no /norestart
;********************************************************************************************************************************************

Im solo-paket brauchst du den [Initial] und [Aktions] Bereich, weil du ja sicherlich auch Pakete einzeln installieren willst.

Bis dann!

Hi jcconnor,
das hört sich super an, sowas ähnliches hab ich mir auch schon gedacht, hab es aber für viel komplizierter gehalten. Ich werdes ausprobieren, aber ich denke das ist genau das was ich gesucht habe.
Danke und Gruß
Sven