forum.opsi.org

opsi support forum
https://forum.opsi.org/

Java-Installation hängt

https://forum.opsi.org/viewtopic.php?t=3215

Seite 2 von 2

Re: Java-Installation hängt

Verfasst: 12 Jan 2012, 12:25
von Andrago
gleicher Fehler, habe winst und opsi-client-agent up-to-date:

Code: Alles auswählen

[5] [12.01.2012 09:35:57]   Else
[5] [12.01.2012 09:35:57]     message Installing Sun jre1.6.0_30 32 Bit...
[5] [12.01.2012 09:35:57]     
[5] [12.01.2012 09:35:57]     If
[5] [12.01.2012 09:35:57]       $INST_SystemType$ = "64 Bit System"   <<< result false
[5] [12.01.2012 09:35:57]     Then
[5] [12.01.2012 09:35:57]     EndIf
[5] [12.01.2012 09:35:57]     
[5] [12.01.2012 09:35:57]     Execution of Winbatch_sun_1_6_silent_install_32
[6] [12.01.2012 09:35:57]       Call "X:\javavm\jre-6u30-windows-i586.exe /s /v"/qb-! /lie c:\tmp\jre1.6.0_30.log ADDLOCAL=ALL IEXPLORER=1 MOZILLA=1  REBOOT=ReallySuppess SYSTRAY=0 JAVAUPDATE=0 JU=0 AUTOUPDATECHECK=0 ARPURLUPDATEINFO='http://www.opsi.org'""
[6] [12.01.2012 09:35:57]          Waiting until the called process is finished
[7] [12.01.2012 09:35:58]       Waiting for ending at 12.01.2012 09:35:58 exitcode is: 259
[7] [12.01.2012 09:35:59]       Waiting for ending at 12.01.2012 09:35:59 exitcode is: 259
[7] [12.01.2012 09:36:00]       Waiting for ending at 12.01.2012 09:36:00 exitcode is: 259
[7] [12.01.2012 09:36:01]       Waiting for ending at 12.01.2012 09:36:01 exitcode is: 259
Waiting (...) kommt halt bis man den Rechner neu startet.

Re: Java-Installation hängt

Verfasst: 12 Jan 2012, 13:29
von d.oertel
Hi,

der exitcode 259 bedeutet, das der thread noch aktiv ist.
Von daher verhält sich der winst korrekt.

Wir empfehlen die Pakete aus dem opsi Abo.

mal vor dem winbatch aufruf einfügen:

Code: Alles auswählen

Execwith_autoit_close_proxy "%SCRIPTPATH%\autoit3.exe" WINST /letThemGo
nach dem sub_check

Code: Alles auswählen

Killtask "autoit3.exe"

Code: Alles auswählen

[Execwith_autoit_close_proxy]
WinWait("Verbindung","Verbindung")
Sleep(500)
; activating
WinActivate("Verbindung","Verbindung")
send ("!{F4}")
exit
die autoit3.exe in den %ScriptPath% legen.

gruss
d.oertel

Re: Java-Installation hängt

Verfasst: 13 Jan 2012, 08:25
von Andrago
damit läufts! DANKE!

Re: [GELÖST] Java-Installation hängt

Verfasst: 13 Jan 2012, 10:39
von d.oertel
Hi,

hättest Du die Pakete aus dem Abo, hättest Du viel Zeit gespart - rechne das mal durch ....

gruss
d.oertel

Re: Java-Installation hängt

Verfasst: 16 Jan 2012, 12:37
von Andrago
geht doch noch nicht so ganz.
Habe das gerade nochmal getestet.
Nun bekomme ich aber immer folgende Meldung:
"Es sind keine Sperrinformationen für das Sicherheitszertifikat dieser Site verfügbar. Möchten Sie den Vorgang fortgesetzen?"
Das ganze muss ich mit JA bestätigen, dann läuft die Installation durch.

Re: Java-Installation hängt

Verfasst: 30 Jan 2012, 10:24
von Andrago
hat niemand sonst das Problem mit der Abfrage bzgl. des Sicherheitszertifikats?! :(

Re: Java-Installation hängt

Verfasst: 20 Feb 2012, 11:03
von ant
Hallo,

unsere Clients (nur XP und auch nicht alle) bekommen die gleiche Meldung:
"Es sind keine Sperrinformationen für das Sicherheitszertifikat dieser Site verfügbar. Möchten Sie den Vorgang fortgesetzen?"

Irgendwo habe ich gelesen, dass es bei den Clients keine Internet-Verbindung wegen der Firewal/Proxy Einstellungen gibt.
Trotzdem ist es seltsam, dass diese Meldung erst jetzt beim Java 1.6 Update 31 vorkommt.

Re: Java-Installation hängt

Verfasst: 01 Mär 2012, 08:07
von kniggisiggi
überprüfe die systemzeit des clients!

Re: Java-Installation hängt

Verfasst: 29 Apr 2012, 21:38
von w42k
Aktuelle Java welche mit Firefox 10.0.4 ESR mitspielt herunterladen
http://www.oracle.com/technetwork/java/ ... 94646.html

läuft auf winXP 32 und win7 64

Code: Alles auswählen

; Copyright (c) uib gmbh (www.uib.de)
; This sourcecode is owned by uib
; and published under the Terms of the General Public License.

[Aktionen]
requiredWinstVersion >= "4.10.3"
Message "installing Java Virtual Machine Sun 1.6 ..."
DefVar $ExitCode$
DefVar $INST_MsVersion$
DefVar $INST_SystemType$
DefVar $INST_architecture$
DefVar $JAVA32_16EXE$
DefVar $JAVA32_16VER$
DefVar $JAVA64_16EXE$
DefVar $JAVA64_16VER$
DefVar $UninstallCommand$
DefVar $DisplayName$
DefVar $InstallPlugins$
DefVar $MySystemRoot$

DefStringlist $INST_MsVersionMap$

Set $INST_SystemType$ = GetSystemType
set $INST_MsVersion$ = GetMsVersionInfo
set $INST_MsVersionMap$ = GetMSVersionMap
set $INST_architecture$ = GetProductProperty("install_architecture","system specific")
set $MySystemRoot$ = "%"+"systemroot"+"%"

set $JAVA32_16EXE$="jre-6u32-windows-i586.exe"
set $JAVA32_16VER$="jre1.6.0_32"
set $JAVA64_16EXE$="jre-6u32-windows-i586.exe"
set $JAVA64_16VER$="jre1.6.0_32"
set $InstallPlugins$ = "IEXPLORER=1 MOZILLA=1"

if not(HasMinimumSpace ("%SYSTEMDRIVE%", "200 MB"))
	LogError "Not enough space on %SystemDrive%, " + $MinimumSpace$ + " on drive %SystemDrive% needed for Java 1.6"
	isFatalError
	; Stop process and set installation status to failed
endif

if $INST_MsVersion$ < "5.0"
	LogError "Minimum Windows 2000 is required for Java 1.6" 
	isFatalError
endif

ShowBitmap "%scriptpath%\java.png" "SUN Java VM"

if FileExists("%ScriptPath%\subdeljava.ins") 
	comment "start uninstall"
	sub "%ScriptPath%\subdeljava.ins"
endif

comment "installing"

if (($INST_SystemType$ = "x86 System") and ($INST_architecture$ = "system specific")) or ($INST_architecture$ = "both") or ($INST_architecture$ = "32 only")
	if ($INST_MsVersion$ = "6.0") and ("1" < getValue("product_type_nr",$INST_MsVersionMap$)) and ($INST_SystemType$ = "64 Bit System")
		LogWarning "silent installation on 2008x64 doesn't works at the moment"
	else
		Message "Installing Sun "+$JAVA32_16VER$+ " 32 Bit..."
		if $INST_SystemType$ = "64 Bit System"
			comment "registry hack for silent install 32 bit on 64 Bit Systems"
			; see http://www.myitforum.com/forums/tm.aspx?high=&m=215451&mpage=1#215451
			Registry_redirect_64_profile_image_to_32 /64bit
		endif
		killtask "javaw.exe"
		killtask "firefox.exe"
		killtask "iexplore.exe"
		Winbatch_sun_1_6_silent_install_32
		if $INST_SystemType$ = "64 Bit System"
			comment "registry hack for silent install 32 bit on 64 Bit Systems"
			Registry_redirect_64_profile_image_to_64 /64bit
		endif
		Sub_check_exitcode
		comment "disable auto updater"
		; see http://wpkg.org/Java
		Winbatch_sun_1_6_silent_disable_update
		;Sub_check_exitcode
		Registry_disable_update
	endif
endif ; 32 Bit

if ($INST_SystemType$ = "64 Bit System") and (($INST_architecture$ = "system specific") or ($INST_architecture$ = "both") or ($INST_architecture$ = "64 only"))
	Message "Installing Sun "+$JAVA64_16VER$+ " 64 Bit..."
	killtask "javaw.exe"
	killtask "firefox.exe"
	killtask "iexplore.exe"
	Winbatch_sun_1_6_silent_install_64
	Sub_check_exitcode
	comment "disable auto updater"
	; see http://wpkg.org/Java
	Registry_disable_update /64Bit
endif ; 64 Bit


; custom specific stuff
if FileExists("%ScriptPath%\custom_ins_dir\custom.ins")
	sub "%ScriptPath%\custom_ins_dir\custom.ins"
endif


[Sub_check_exitcode]
comment "Test for installation success via exit code"
set $ExitCode$ = getLastExitCode
; informations to exit codes see
; http://msdn.microsoft.com/en-us/library/aa372835(VS.85).aspx
; http://msdn.microsoft.com/en-us/library/aa368542.aspx
if ($ExitCode$ = "0")
	comment "Looks good: setup program gives exitcode zero"
else
	comment "Setup program gives a exitcode unequal zero: " + $ExitCode$
	if ($ExitCode$ = "1605")
		comment "ERROR_UNKNOWN_PRODUCT	1605	This action is only valid for products that are currently installed."
		comment "Uninstall of a not installed product failed - no problem"
	else
		if ($ExitCode$ = "1641")
			comment "looks good: setup program gives exitcode 1641"
			comment "ERROR_SUCCESS_REBOOT_INITIATED	1641	The installer has initiated a restart. This message is indicative of a success."
		else
			if ($ExitCode$ = "3010")
				comment "looks good: setup program gives exitcode 3010"
				comment "ERROR_SUCCESS_REBOOT_REQUIRED	3010	A restart is required to complete the install. This message is indicative of a success."
			else
				logError "Fatal: Setup program gives an unknown exitcode unequal zero: " + $ExitCode$
				isFatalError
			endif
		endif
	endif
endif

[winbatch_start_taskmgr]
taskmgr.exe

[Winbatch_sun_1_6_silent_disable_update]
msiexec /x {4A03706F-666A-4037-7777-5F2748764D10} /qb-!

[Registry_redirect_64_profile_image_to_32]
openkey [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\S-1-5-18]
set "ProfileImagePath"=REG_EXPAND_SZ:"$MySystemRoot$\syswow64\config\systemprofile"

[Registry_redirect_64_profile_image_to_64]
openkey [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList\S-1-5-18]
set "ProfileImagePath"=REG_EXPAND_SZ:"$MySystemRoot$\config\systemprofile"

[Registry_disable_update]
openkey [HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Update\Policy]
set "EnableJavaUpdate"=REG_DWORD:0

[Winbatch_sun_1_6_silent_install_32]
"%SCRIPTPATH%\$JAVA32_16EXE$" /lang=1031 /s $InstallPlugins$ REBOOT=Suppress

[Winbatch_sun_1_6_silent_install_64]
"%SCRIPTPATH%\$JAVA64_16EXE$" /lang=1031 /s $InstallPlugins$ REBOOT=Suppress

[Winbatch_sun_uninstall]
$UninstallCommand$
Alle Zeiten sind UTC+02:00
Seite 2 von 2

Powered by phpBB® Forum Software © phpBB Limited

Deutsche Übersetzung durch phpBB.de