WAN/VPN Extension und Local Cached Product Propertys

[Chris81]

Hallo zusammen,

erst einmal schön hier zu sein.

Wir nutzen die kommerzielle WAN/VPN Extension um unsere Benutzer so wenig wie möglich zu stören. Das klappt auch wunderbar. Allerdings bin ich jetzt auf ein Problem beim Testen unseres BitLocker Pakets gestoßen. Der Wiederherstellungschlüssel soll wenn das System bereits verschlüsselt ist an den Server übermittelt werden. Das funktioniert über OpsiServericeCall und deaktivieter WAN/VPN Extension wunderbar aber mit nicht. Der Client schreibt die aktuelle Property zwar immer in die Local Cached Propertys aber überträgt sie bei der nächsten Verbindung nicht an den Server. Action States ie Success oder Failed überträgt der Client. Die Client Config sieht ebenfalls so aus wie sie sollte. Laut offiziellen Quellen sollte das funktionieren? Schwer sonst etwas dazu im Netz zu finden. Ist es normal das das nicht funktioniert?

Danke für eure Hilfe

[magicalUnicorn]

Hallo zusammen,

erst einmal schön hier zu sein.

Wir nutzen die kommerzielle WAN/VPN Extension um unsere Benutzer so wenig wie möglich zu stören. Das klappt auch wunderbar. Allerdings bin ich jetzt auf ein Problem beim Testen unseres BitLocker Pakets gestoßen. Der Wiederherstellungschlüssel soll wenn das System bereits verschlüsselt ist an den Server übermittelt werden. Das funktioniert über OpsiServericeCall und deaktivieter WAN/VPN Extension wunderbar aber mit nicht. Der Client schreibt die aktuelle Property zwar immer in die Local Cached Propertys aber überträgt sie bei der nächsten Verbindung nicht an den Server. Action States ie Success oder Failed überträgt der Client. Die Client Config sieht ebenfalls so aus wie sie sollte. Laut offiziellen Quellen sollte das funktionieren? Schwer sonst etwas dazu im Netz zu finden. Ist es normal das das nicht funktioniert?

Danke für eure Hilfe

Wie sieht denn dein OpsiServiceCall dafür aus im Skript? Bei uns klappt das setzen von Properties via WAN/VPN eigentlich ganz gut bisher

[Chris81]

Gerne, hier:

OpsiServiceCall_SetProductProperty

Code: Alles auswählen

[Actions]
RequiredWinstVersion >= "4.12.17.2"

DefStringList $FileResult$
DefVar $IsBitLockerActive$
DefVar $RecoveryPassword$
DefVar $SupportedVersion$
DefVar $SupportedType$
DefVar $SystemVersion$
DefVar $PasswordFile$
DefVar $SupportedOS$
DefVar $ProductName$
DefVar $ProductLogo$
DefVar $ProductFile$
DefVar $TargetDrive$
DefVar $SystemType$
DefVar $SystemOS$
DefVar $ExitCode$

Set $IsBitLockerActive$ = GetProductProperty("bitlocker_active", "")
Set $PasswordFile$ = "%OpsiTmpDir%\recovery_password.txt"
Set $ProductFile$ = "%ScriptPath%\setup.ps1"
Set $ProductLogo$ = "%ScriptPath%\logo.png"
Set $ProductName$ = "BitLocker-Verwaltung"

ShowBitmap $ProductLogo$ $ProductName$
Sub_Check_System_Requirements
Sub_Save_Recovery_Password
Sub_Execute_Product
Sub_Load_Recovery_Password
Sub_Check_Product_Executed

[Sub_Check_System_Requirements]
Message "Check if host meets the system requirements ..."
SleepSeconds 3
Set $SystemVersion$ = GetMsVersionName
Set $SupportedType$ = "64 Bit System"
Set $SystemType$ = GetSystemType
Set $SupportedOS$ = "Windows_NT"
Set $SupportedVersion$ = "11.0"
Set $SystemOS$ = GetOS
if not(($SystemOS$ = $SupportedOS$) and ($SystemVersion$ = $SupportedVersion$) and ($SystemType$ = $SupportedType$))
	Message "Host does not meet the system requirements"
	SleepSeconds 3
	LogError "Host does not meet the system requirements"
	IsFatalError
endif

[Sub_Save_Recovery_Password]
Message "Save recovery password to disk ..."
SleepSeconds 3
Set $RecoveryPassword$ = GetProductProperty("recovery_password", "")
if not(SaveTextFile(CreateStringList($RecoveryPassword$), $PasswordFile$))
	Message "Recovery password cannot be saved to disk"
	SleepSeconds 3
	LogError "Recovery password cannot be saved to disk"
	IsFatalError
endif

[Sub_Load_Recovery_Password]
Message "Load recovery password from disk ..."
SleepSeconds 3
if (FileExists($PasswordFile$))
	Set $FileResult$ = LoadTextFile($PasswordFile$)
	Set $RecoveryPassword$ = TakeString(0, $FileResult$)
	OpsiServiceCall_SetProductProperty
	Files_Delete_Recovery_Password
else
	Message "Recovery password cannot be loaded from disk"
	SleepSeconds 3
	LogError "Recovery password cannot be loaded from disk"
	IsFatalError
endif

[Files_Delete_Recovery_Password]
delete -f $PasswordFile$

[Sub_Execute_Product]
if ($IsBitLockerActive$ = "True")
	Message "Activate BitLocker ..."
else
	Message "Deaktivate BitLocker ..."
endif
SleepSeconds 3
Set $TargetDrive$ = GetProductProperty("target_drive", "")
ShellScript_Execute_Product

[ShellScript_Execute_Product]
powershell -ExecutionPolicy "Bypass" -File $ProductFile$ -IsBitLockerActive $IsBitLockerActive$ -TargetDrive $TargetDrive$ -PasswordFile $PasswordFile$

[OpsiServiceCall_SetProductProperty]
"method": "setProductProperty"
"params": [
						"win11-management-bitlocker",
            "recovery_password",
            "$RecoveryPassword$",
            "%HostID%"
          ]

[Sub_Check_Product_Executed]
Set $ExitCode$ = GetLastExitCode
if ($ExitCode$ = "0")
	if ($IsBitLockerActive$ = "True")
		Message "BitLocker has been successfully activated"
		SleepSeconds 3
		IsSuccess
	else
		Message "BitLocker has been successfully deactivated"
		SleepSeconds 3
		IsSuccess
	endif
elseif ($ExitCode$ = "101")
	Message "An error has occurred during encryption, execution is canceled"
	SleepSeconds 3
	LogError "An error has occurred during encryption, execution is canceled (Error code: " + $ExitCode$ + ")"
	IsFatalError
elseif ($ExitCode$ = "102")
	Message "An error has occurred during decryption, execution is canceled"
	SleepSeconds 3
	LogError "An error has occurred during decryption, execution is canceled (Error code: " + $ExitCode$ + ")"
	IsFatalError
elseif ($ExitCode$ = "103")
	Message "An unknown value was specified, execution is canceled"
	SleepSeconds 3
	LogError "An unknown value was specified, execution is canceled (Error code: " + $ExitCode$ + ")"
	IsFatalError
elseif ($ExitCode$ = "104")
	Message "No target drive was found, execution is canceled"
	SleepSeconds 3
	LogError "No target drive was found, execution is canceled (Error code: " + $ExitCode$ + ")"
	IsFatalError
elseif ($ExitCode$ = "105")
	Message "Status could not be determined, execution is canceled"
	SleepSeconds 3
	LogError "Status could not be determined, execution is canceled (Error code: " + $ExitCode$ + ")"
	IsFatalError
elseif ($ExitCode$ = "106")
	Message "BitLocker is already active"
	SleepSeconds 3
	IsSuccess
elseif ($ExitCode$ = "107")
	Message "BitLocker is already inactive"
	SleepSeconds 3
	IsSuccess
elseif ($ExitCode$ = "108")
	Message "Target drive is locked, execution is canceled"
	SleepSeconds 3
	LogError "Target drive is locked, execution is canceled (Error code: " + $ExitCode$ + ")"
	IsFatalError
else
	Message "An unexpected error has occurred, execution is canceled"
	SleepSeconds 3
	LogError "An unexpected error has occurred, execution is canceled (Error code: " + $ExitCode$ + ")"
	IsFatalError
endif

opsiclientd.conf

Code: Alles auswählen

[event_sync]
super = default
type = template
process_actions = false
event_notifier_command = 
sync_config_to_server = true
sync_config_from_server = true
cache_products = true
cache_dynamic_bandwidth = true

[event_sync_completed]
super = default
type = sync completed
event_notifier_command = 
process_actions = false
get_config_from_service = false
write_log_to_service = false

Die cached_productpropertyvalues.json passt er an aber das recovery_passwort sendet er dann nicht. Mittlerweile ist der Eintrag für das Paket raus, also durch.

Screenshot 2025-06-10 102836.png (10.24 KiB) 270 mal betrachtet

[Chris81]

Wie bereits gesagt, ohne WAN/VPN Extension funktionierts.

[Chris81]

Update!

Ich kann nicht sagen warum aber ich habe jetzt weitere Tests bei anderen Benutzern durchgeführt und ich kann bestätigen das es doch funktioniert. Hoffe das läuft alles zuverlässig.

Danke trotzdem