Internet Explorer 8 (IE8) Opsi-Paket ?

[chhaas]

Hallo,

ich bin hier am verzweifeln mit dem Internet Explorer 8 - Wie immer ich auch versuche ein IE8-Opsi-Paket zu bauen (als Quelle das "normale" IE8-WindowsXP-x86-DEU.exe / als Quelle ein mit dem IEAK8 erstelltes MSI-Paket, in Opsi als "normales" Setup-Skript / mit Opsi als lokaler Administrator) - der IE8 funktioniert hier halt nicht ...

Hat hier jemand erfolgreich ein IE8-Paket (oder zur Not auch IE7) gebaut und kann mich auf die richtige Spur setzen??? (Klasse waere natuerlich das Opsi-Installationsskript).

Schon jetzt herzlichen Dank und Gruss
Christoph.

[lenny]

Ich versuchse auch das meinste über den Opsi abzubilden, aber in diesem Fall ist es doch der Weg über die Brust ins Auge, zuminestst wenn man einen WSUS hat. Oder binde die Installation über das MSI Paket über die AD ein.

Grüßle Lenny

[eih]

Mit Hilfe der Musterpakete habe ich folgende Version des Installationsskriptes gebaut:

Code: Alles auswählen

Message=Installiere Internet Explorer 8
[Initial]
LogLevel=2
;  Log Errors in Logfile but don't abort:
ExitOnError=true
; Show syntax errors in the script:
ScriptErrorMessages=on
; Dont trace step by step through the script:
TraceMode=off
; let started programs run in front of the winst window
StayOnTop=false
 
[Aktionen]
DefVar $ProductId$
DefVar $MinimumSpace$
DefVar $NewExe$
DefVar $InstallDir$
DefVar $OS$
DefVar $WinstRegKey$
DefVar $Flag$
DefVar $RebootRegVar$
DefVar $TEMP$ 

Set $TEMP$ = EnvVar("TEMP")
set $ProductId$ = "ie8"
set $MinimumSpace$ = "50 MB"
set $InstallDir$="C:\WINDOWS\ie8"
set $NewExe$=$InstallDir$+"\iexplore.exe"

set $OS$=EnvVar("OS")
if $OS$="Windows_NT"
		Set $WinstRegKey$ = "HKLM\SOFTWARE\opsi.org\winst"
		Set $Flag$ = GetRegistryStringValue ("["+$WinstRegKey$+"] "+"RebootFlag")
		if not ($Flag$ = "1")
			;=========================
			; Anweisungen vor Reboot
			; Message at install time:
			Message "Installing "+$ProductId$+" ..."

				if not(HasMinimumSpace ("%SYSTEMDRIVE%", $MinimumSpace$))
					   LogError "Not enough space on C: . "+$MinimumSpace$+" auf C: fuer "+$ProductId$+" erforderlich."
					   isFatalError
					   ; Bearbeitung beenden und Produktschalter auf failed setzen
				else
						 ;show product picture
						ShowBitmap /3 "%scriptpath%\"+$ProductId$+".png" "Internet Explorer 8"


						;Message at install time:
						Message "Installing "+$ProductId$+" ..."
						;start setup program  
						Winbatch_install
						comment "test for installation success"
						if not(FileExists($NewExe$))
							logError "Fatal: After Installation "+$NewExe$+" not found"
							 ; Rebootflag zurücksetzen
							Set $Flag$ = "0"
							Registry_SaveRebootFlag
							isFatalError
						endif
				endif
			; Reboot initialisieren ...
			Set $Flag$ = "1"
			Registry_SaveRebootFlag
			ExitWindows /ImmediateReboot
		else
			;=========================
			; Anweisungen nach Reboot
			; Rebootflag zurücksetzen
			Set $Flag$ = "0"
			Registry_SaveRebootFlag
		endif
endif


[Registry_SaveRebootFlag]
openKey [$WinstRegKey$]
set "RebootFlag" = "$Flag$"


[Winbatch_install]
%SCRIPTPATH%\IE8-WindowsXP-x86-DEU.exe /passive /norestart

Für das Paket braucht man noch das Setuppaket. Ich habe das genommen, was man mit WSUS Offline Update http://www.wsusoffline.net/ erhält.
(Den Namen etwas gekürzt.)
Und optional noch ein png für den Bildschirm.

Das Skript funktioniert bei Neuinstallationen problemlos, bei einigen wenigen Altinstallationen harkte es.
Also Benutzung auf eigene Gefahr.

Viele Grüße

eih