ich habe ein Problem mit der Swyx Installation. Die Installation selbst läuft. Er installiert Swyx und Konfiguriert so wie er es soll.
Aber, wenn ich die Software dann das erste mal starte, dann löscht Swyx aus irgendeinem Grund ein paar *.dll Dateien aus dem SysWOW64 Ordner.
Im gleichen Ordner erstellt er dann lauter Dateien die ungefähr so heißen: C_437.NLS
Dies killt dann ein paar Programme. Warenwirtschaftssystem (R+H AS400), Adobe Reader ... etc...
Code: Alles auswählen
[Actions]
requiredWinstVersion >= "4.10.8.6"
DefVar $ExitCode$
DefVar $ProductId$
DefVar $ProductName$
DefVar $MinimumSpace$
DefVar $_allow_reboot$
DefStringList $languageInfo$
DefVar $oslanguage$
DefVar $language$
DefVar $swyxEN$
DefVar $swyxDE$
DefVar $activate_balloon_tips$
set $ProductId$ = "swyxit"
set $ProductName$ = "SwyxIt! 2015"
set $MinimumSpace$ = "250 MB"
set $_allow_reboot$ = GetProductProperty("_allow_reboot","True")
set $languageInfo$ = getLocaleInfoMap
set $oslanguage$ = getValue("language_id_2chars", $languageInfo$)
set $language$ = GetProductProperty("language","OS")
set $swyxEN$ = "SwyxIt!EnglishUK64.msi"
set $swyxDE$ = "SwyxIt!German64.msi"
set $activate_balloon_tips$ = GetProductProperty("activate_balloon_tips","True")
if not(HasMinimumSpace ("%SystemDrive%", $MinimumSpace$))
LogError "Not enough space on %SystemDrive%, " + $MinimumSpace$ + " on drive %SystemDrive% needed for " + $ProductId$
isFatalError
; Stop process and set installation status to failed
else
comment "Show product picture"
ShowBitmap "%ScriptPath%\" + $ProductId$ + ".png" $ProductName$
if FileExists("%ScriptPath%\delsub.ins")
comment "Start uninstall sub section"
Sub "%ScriptPath%\delsub.ins"
endif
;Prüfung / Installation .net Framework 4.5.1 Full
DefVar $DisplayName$
set $DisplayName$ = GetRegistryStringValueSysNative("[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{7DEBE4EB-6B40-3766-BB35-5CBBC385DA37}] DisplayName")
if ($DisplayName$ = "")
Message "Installiere .net Framework 4.5.1 Full..."
Winbatch_Install_netFramework
else
Message ".net Framework 4.5.1 Full bereits installiert."
endif
Message "Installing " + $ProductName$ + " ..."
comment "Start setup program"
if ($language$ = "OS")
if $oslanguage$="DE"
; installiere deutsche Version
Winbatch_install_de
else
; installiere englische Version
Winbatch_install_en
endif
endif
if ($language$ = "GER")
Winbatch_install_de
endif
if ($language$ = "EN")
Winbatch_install_en
endif
Files_copy_LotusNotesAccess
Registry_set_swyxit_server /AllNTUserdats /SysNative
Registry_disable_tipsonstartup_swyxit /AllNTUserdats /SysNative
Registry_disable_calender_options_swyxit /AllNTUserdats /SysNative
Registry_disable_pbx_server_auto_detection_swyxit /AllNTUserdats /SysNative
Registry_set_faxclient_server /AllNTUserdats /SysNative
Registry_disable_pbx_server_auto_detection_faxclient /AllNTUserdats /SysNative
if ($activate_balloon_tips$ = "True")
Registry_hklm_enable_balloon_tips /SysNative
Registry_hkcu_enable_balloon_tips /AllNTUserdats /SysNative
endif
sub "%ScriptDrive%\check_exitcode\check_msi-exitcode.ins"
;Neustart des Rechners
if ($_allow_reboot$ = "True")
ExitWindows /Reboot
endif
endif
[Winbatch_Install_netFramework]
%ScriptPath%\NDP451-KB2858728-x86-x64-AllOS-ENU.exe /q /norestart
[Winbatch_install_de]
msiexec /i %ScriptPath%\SwyxIt!German64.msi /qb ADDLOCAL="PhoneClient,ScriptEditor,Video,ClientMeeting,NotesAccess,CLMgrTSP,DesktopShortcut,FaxClient,Quickstart"
;StartupShortcut,EstosAccess (VisualContacts AddIn)
[Winbatch_install_en]
msiexec /i %ScriptPath%\SwyxIt!EnglishUK64.msi /qb ADDLOCAL="PhoneClient,ScriptEditor,Video,ClientMeeting,NotesAccess,CLMgrTSP,DesktopShortcut,FaxClient,Quickstart"
;StartupShortcut,EstosAccess (VisualContacts AddIn)
[Files_copy_LotusNotesAccess]
copy "%ScriptPath%\LotusNotesAccess.exe" "%ProgramFiles32Dir%\SwyxIt!\"
[Registry_set_swyxit_server]
OpenKey [Software\Swyx\SwyxIt!\CurrentVersion\Options]
set "PbxServer" = REG_SZ:"swyx.local"
[Registry_disable_tipsonstartup_swyxit]
OpenKey [Software\Swyx\SwyxIt!\CurrentVersion\Options]
set "TipsOnStartUp" = REG_DWORD:0x0
[Registry_disable_calender_options_swyxit]
OpenKey [Software\Swyx\SwyxIt!\CurrentVersion\Options]
set "AppointmentDetection" = REG_DWORD:0x0
set "AppointmentDetectionSubject" = REG_DWORD:0x0
[Registry_disable_pbx_server_auto_detection_swyxit]
OpenKey [Software\Swyx\SwyxIt!\CurrentVersion\Options]
set "UsePbxServerFromAutoDetection" = REG_DWORD:0x0
[Registry_set_faxclient_server]
OpenKey [Software\Swyx\FaxClient\CurrentVersion\Options]
set "PbxServer" = REG_SZ:"swyx.local"
[Registry_disable_pbx_server_auto_detection_faxclient]
OpenKey [Software\Swyx\FaxClient\CurrentVersion\Options]
set "UsePbxServerFromAutoDetection" = REG_DWORD:0x0
[Registry_hklm_enable_balloon_tips]
OpenKey [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced]
set "EnableBalloonTips" = REG_DWORD:0x1
[Registry_hkcu_enable_balloon_tips]
openKey [HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced]
set "EnableBalloonTips"=REG_DWORD:0x1
Warum und wieso, keine Ahnung.
Hat jemand schon ähnliche Erfahrungen gemacht oder verteilt SwyxIt! erfolgreich über den OPSI?
Eine Installation von Hand funktioniert...
Danke
hadro