This is an old revision of the document!


Remote Desktop Manager

Tested with opsi 4.0.4

Der Remote Desktop Manager kann hier runtergeladen werden: http://remotedesktopmanager.com/Home/Download

In den RemoteDesktopManager.cfg Dateien muss der <string> Part angepasst werden. Diese besagt, wo die exportierten Server Listen gespeichert wurden und wie die .rdm Datei heißt.

Zu finden ist die Original cfg unter: “%LocalAppData%\Devolutions\RemoteDesktopManager” …

Dieses Script konfiguriert durch die RemoteDesktopManager.cfg sofort die Standard und nicht die Enterprise Version. Dafür wurde nur 2 Zeilen aus der Original cfg gelöscht, welche den Trial Key für die Enterprise Version enthielten.

setup.ins

[Actions]
requiredWinstVersion >= "4.11.2.6"
 
DefVar $ProductId$
DefVar $ProductName$
DefVar $MinimumSpace$
DefVar $oslanguage$
DefVar $language$
DefStringList $languageInfo$
 
DefVar $ExitCode$
 
set $ProductId$			= "remotedesktopmanager"
set $ProductName$		= "Remote Desktop Manager"
set $MinimumSpace$ 		= "160 MB"
set $languageInfo$      = getLocaleInfoMap
set $oslanguage$        = getValue("language_id_2chars", $languageInfo$)
set $language$		  	= GetProductProperty("language","OS")
 
Message "Installing " + $ProductName$ + " ..."
 
if not(HasMinimumSpace ("%SYSTEMDRIVE%", $MinimumSpace$))
	LogError "Not enough space on %SYSTEMDRIVE%: . " + $MinimumSpace$ + " on Drive %SYSTEMDRIVE%: needed for " + $ProductId$ + "."
	isFatalError
else
	comment "show product picture"
	ShowBitmap "%ScriptPath%\" + $ProductId$ + ".png" $ProductName$
 
	if FileExists("%ScriptPath%\delsub.ins")
		comment  "start uninstall sub section"
		sub "%ScriptPath%\delsub.ins"
	endif
 
	Message "Installing " + $ProductName$ + " ..."
 
	comment "Start setup program"
	Registry_config /AllNTUserdats /SysNative
 
	Winbatch_install_rdm
 
	sub "%ScriptDrive%\check_exitcode\check_msi-exitcode.ins"
 
	if ($language$ = "OS")
		if $oslanguage$="DE"
			; installiere deutsche Version
			Files_copy_cfg_server_de
		else
			; installiere englische Version
			Files_copy_cfg_server_en
		endif
	endif
 
	if ($language$ = "GER")
		Files_copy_cfg_server_de
	endif
 
	if ($language$ = "EN")
		Files_copy_cfg_server_en
	endif
 
	Files_copy_serverlist
endif
 
[Winbatch_install_rdm]
%ScriptPath%\Setup.RemoteDesktopManager.9.2.2.0.exe /q
 
[Registry_config]
OpenKey [HKCU\Software\RemoteDesktopManager]
add "OptionPath" = REG_SZ:"%ProgramFiles32Dir%\Devolutions\Remote Desktop Manager\cfg\"
 
[Files_copy_cfg_server_de]
copy "%ScriptPath%\cfg_de\*.*" "%ProgramFiles32Dir%\Devolutions\Remote Desktop Manager\cfg\"
 
[Files_copy_cfg_server_en]
copy "%ScriptPath%\cfg_en\*.*" "%ProgramFiles32Dir%\Devolutions\Remote Desktop Manager\cfg\"
 
[Files_copy_serverlist]
copy "%ScriptPath%\SERVERLISTE.rdm" "%ProgramFiles32Dir%\Devolutions\Remote Desktop Manager\cfg\"

delsub.ins

DefVar $DisplayName$
DefVar $UninstallCommand$
 
set $DisplayName$ = GetRegistryStringValueSysNative("[HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{4C57681A-37FF-4DAB-9ECE-60D180EDEA75}] DisplayName")
if not ($DisplayName$ = "")
	Message "Deinstalling " + $ProductName$ + " ..."
	set $UninstallCommand$ = "MsiExec.exe /x {4C57681A-37FF-4DAB-9ECE-60D180EDEA75} /qn REBOOT=ReallySuppress"
	Winbatch_Uninstall
	DosInAnIcon_uninstall
	sub "%ScriptDrive%\check_exitcode\check_msi-exitcode.ins"
endif
 
[Winbatch_Uninstall]
$UninstallCommand$
 
[DosInAnIcon_uninstall]
rmdir /S /Q "%ProgramFiles32Dir%\Devolutions"

uninstall.ins

[Actions]
requiredWinstVersion >= "4.11.2.6"
 
DefVar $ProductId$
DefVar $ProductName$
 
DefVar $ExitCode$
 
set $ProductId$			= "remotedesktopmanager"
set $ProductName$		= "Remote Desktop Manager"
 
comment "show product picture"
ShowBitmap "%ScriptPath%\" + $ProductId$ + ".png" $ProductName$
 
if FileExists("%ScriptPath%\delsub.ins")
	comment  "start uninstall sub section"
	sub "%ScriptPath%\delsub.ins"
endif

OPSI/control

[Package]
version: 1
depends: 
incremental: False
 
[Product]
type: localboot
id: remotedesktopmanager
name: Remote Desktop Manager
description: 
advice: Firefox und Putty (AdminUtils) können nach installiert werden, damit RDM darauf zugreifen kann.
version: 9.2.2.0
priority: 0
licenseRequired: False
productClasses: 
setupScript: setup.ins
uninstallScript: uninstall.ins
updateScript: 
alwaysScript: 
onceScript: 
customScript: 
userLoginScript: 
 
[ProductProperty]
type: unicode
name: language
multivalue: False
editable: True
description: Auswahl der Sprache. Standard: OS Language = Office Language
values: ["EN", "GER", "OS"]
default: ["OS"]
 
[Changelog]
remotedesktopmanager (9.2.2.0-1) testing; urgency=low

RemoteDesktopManager.cfg - Deutsch

<?xml version="1.0"?>
<Option>
  <CurrentLanguage>de</CurrentLanguage>
  <EditionSelected>true</EditionSelected>
  <EncryptedDataSources>
    <string>!!!!HIER MUSS ANGEPASST WERDEN!!!!</string>
  </EncryptedDataSources>
</Option>

RemoteDesktopManager.cfg - Englisch

<?xml version="1.0"?>
<Option>
  <EditionSelected>true</EditionSelected>
  <EncryptedDataSources>
    <string>!!!!HIER MUSS ANGEPASST WERDEN!!!!</string>
  </EncryptedDataSources>
</Option>

QR Code
QR Code userspace:remote_desktop_manager_9.2.2.0 (generated for current page)