Impossible to uninstall imageresizer (msi)?

Antworten
cyberfrk
Beiträge: 15
Registriert: 03 Mai 2013, 23:10

Impossible to uninstall imageresizer (msi)?

Beitrag von cyberfrk »

Hi everybody,

What must I change in my files to uninstall imageresizer (msi)? I can install but uninstalling is impossible. The winbatch run but Imageresizer is always installed.

Here are my files:
setup32.ins:

Code: Alles auswählen

[Initial]
 
;Standard Text, shown during installation
Message = Merci de patienter, installation en cours
;Set Loglevel
setLogLevel = 6
;Stop when errors
ExitOnError = false
;Les erreurs de syntaxe seront affichees dans une autre fenetre
ScriptErrorMessages = on
;Do not use Single-Step Mode
TraceMode = off
;No winst-window in foreground while batchmode
StayOnTop = false
 
[Actions]
;Variable for the OS
DefVar $OS$
set $OS$ = GetOS
 
;Variable for the OS-Subversion
DefVar $NTVersion$
set $NTVersion$ = GetNTVersion
 
;Variable for the OS-subversion
DefVar $SystemType$
Set $SystemType$ = GetSystemType
 
;Name of product (max. 12 columns)
DefVar $ProductName$
Set $ProductName$ = "imageresizer"
 
;complete name of product incl. versionno.
DefVar $ProductNameFull1$
set $ProductNameFull1$ = "imageresizer"
 
;filename of productpicture with extension
DefVar $ProductPicture$
Set $ProductPicture$ = "imageresizer.png"
 
;filename of MSI-package which has to be installed
DefVar $Executable1$
Set $Executable1$ = "ImageResizer-2.1_x86.msi"
DefVar $Executable2$
Set $Executable2$ = "ImageResizer-2.1_x64.msi"
 
;the variable for the ExitCode
DefVar $ExitCode$
 
;Check the winst-version
requiredWinstVersion >= "4.11"
 
;show $ProductPicture$ and $ProductName$
ShowBitmap /3 "%scriptpath%\" + $ProductPicture$ $ProductName$
 
;Show installation message incl. complete Productname
Message "Installation de "+$ProductNameFull1$
 
;check free diskspace
if not (HasMinimumSpace ("%SYSTEMDRIVE%", "500 MB"))
        LogError "Pas assez de place sur %SYSTEMDRIVE%"
	isFatalError
endif
 
;get OS-Version
;if ( $NTVersion$ = "Win2K" OR $NTVersion$ = "WinXP" OR $NTVersion$ = "Win NT 5.2" OR $NTVersion$ = "Windows Vista" )
	if $SystemType$ = "x86 System"
	Winbatch_Install_32-Bit
	sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"
endif
if $SystemType$ = "64 Bit System"
	Winbatch_Install_64-Bit
	sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"
endif
 
[Winbatch_Install_32-Bit]
msiexec /i "%SCRIPTPATH%\$Executable1$" /qn
 
[Winbatch_Install_64-Bit]
msiexec /i "%SCRIPTPATH%\$Executable2$" /qn
SubUninstall.ins:

Code: Alles auswählen

;Variable pour msiexec afin de desinstaller
DefVar $UninstallCommand$
 
;Variable pour la version de ImageResizer. Provient de la base de registre
DefVar $DisplayName$
 
;Imageresizer 2.1 - cle de registre pour desinstallation
Set $DisplayName$ = GetRegistrystringvalue32("[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{80A620C1-B22C-4781-A351-B14B8A37BFE3}] DisplayName")
if not ($DisplayName$ = "")
	set $UninstallCommand$ = "MsiExec.exe /x {80A620C1-B22C-4781-A351-B14B8A37BFE3} /quiet"
;endif

Message "Desinstallation de "+$DisplayName$
Winbatch_Uninstall
sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"
endif
 
[Winbatch_Uninstall]
$UninstallCommand$
uninstall.ins:

Code: Alles auswählen

[Initial]
Message = Merci de patienter, le produit sera desinstalle
 
;Loglevel einstellen
setLogLevel = 6
 
;Bei Fehlern abbrechen
ExitOnError = false
 
; Les erreurs de syntaxe sont affichées dans une autre fenetre
ScriptErrorMessages = on
 
;Single-Step Mode nicht verwenden
TraceMode = off
 
;Im Batchmode das Winst-Fenster nicht im Vordergrund anzeigen
StayOnTop = false
 
[Actions]
;Variable pour determiner le systeme exploitation
DefVar $OS$
Set $OS$ = GetOS
 
;Variable pour determiner la version du systeme exploitation
DefVar $NTVersion$
Set $NTVersion$ = GetNTVersion
 
;Name des produits
DefVar $ProductName$
Set $ProductName$ = "imageresizer"
 
;Fichier image avec son extension
DefVar $ProductPicture$
Set $ProductPicture$ = "imageresizer.png"
 
; La variable pour les codes de sortie
DefVar $ExitCode$
 
;$ProductPicture$ et $ProductName$
ShowBitmap /3 "%scriptpath%\" + $ProductPicture$ $ProductName$
sub "%ScriptPath%\SubUninstall.ins"
My reg key is ok because when I launch manualy the bash below, Imageresizer is uninstalled...!

Code: Alles auswählen

@echo off
msiexec /uninstall "{80A620C1-B22C-4781-A351-B14B8A37BFE3}" /log "C:\temp\imageresizer_uninstall.txt"
My os is windows 7 64bits
Benutzeravatar
SisterOfMercy
Beiträge: 1522
Registriert: 22 Jun 2012, 19:18

Re: Impossible to uninstall imageresizer (msi)?

Beitrag von SisterOfMercy »

Well, let's see if the problem is with the msi or the script.

Does this function when running as administrator?

Code: Alles auswählen

msiexec.exe /x {80A620C1-B22C-4781-A351-B14B8A37BFE3} /qb-! /l*v "c:\msi-uninstall.log" REBOOT=ReallySuppress
Bitte schreiben Sie Deutsch, when I'm responding in the German-speaking part of the forum!
cyberfrk
Beiträge: 15
Registriert: 03 Mai 2013, 23:10

Re: Impossible to uninstall imageresizer (msi)?

Beitrag von cyberfrk »

Hi SisterOfMercy,

All is ok with your command. Do you want some logs? If yes, witch lines among the 590 lines?
Benutzeravatar
SisterOfMercy
Beiträge: 1522
Registriert: 22 Jun 2012, 19:18

Re: Impossible to uninstall imageresizer (msi)?

Beitrag von SisterOfMercy »

cyberfrk hat geschrieben:All is ok with your command.
Then the issue is within your script.
cyberfrk hat geschrieben:Do you want some logs? If yes, which lines among the 590 lines?
Uh, the log of the msi uninstall? Well, that won't do much good, as that part works.

Can you tell me the url of this imageresizer tool? Is it this one? https://imageresizer.codeplex.com/releases/view/30247
Bitte schreiben Sie Deutsch, when I'm responding in the German-speaking part of the forum!
cyberfrk
Beiträge: 15
Registriert: 03 Mai 2013, 23:10

Re: Impossible to uninstall imageresizer (msi)?

Beitrag von cyberfrk »

SisterOfMercy hat geschrieben: Uh, the log of the msi uninstall? Well, that won't do much good, as that part works.
Sorry, I don't understand, my english isn't very good... :(

In effect, here are the urls of the applications:
32bits: https://imageresizer.codeplex.com/downloads/get/96487
64bits: https://imageresizer.codeplex.com/downloads/get/96488

Thks a lot
Benutzeravatar
SisterOfMercy
Beiträge: 1522
Registriert: 22 Jun 2012, 19:18

Re: Impossible to uninstall imageresizer (msi)?

Beitrag von SisterOfMercy »

Try these:

uninstall3264.ins

Code: Alles auswählen

[Actions]
;SetLogLevel=9
requiredWinstVersion >= "4.10.8.6"

;DefVar $MsiId32$
;DefVar $UninstallProgram32$
;DefVar $MsiId64$
;DefVar $UninstallProgram64$
DefVar $LogDir$
DefVar $ExitCode$
DefVar $ProductId$
;DefVar $InstallDir32$
;DefVar $InstallDir64$
DefVar $INST_SystemType$
;DefVar $INST_architecture$
DefVar $INST_MsVersion$

Set $INST_MsVersion$ = GetMsVersionInfo
Set $INST_SystemType$ = GetSystemType
;set $INST_architecture$ = GetProductProperty("install_architecture","system specific")


Set $LogDir$ = "%SystemDrive%\tmp"

; ----------------------------------------------------------------
; - Please edit the following values                             -
; ----------------------------------------------------------------
Set $ProductId$       = "imageresizer"
;Set $InstallDir32$    = "%ProgramFiles32Dir%\<path to the product>"
;Set $InstallDir64$    = "%ProgramFiles64Dir%\<path to the product>"
; ----------------------------------------------------------------


comment "Show product picture"
ShowBitmap "%ScriptPath%\" + $ProductId$ + ".png" $ProductId$

Message "Uninstalling " + $ProductId$ + " ..."

if FileExists("%ScriptPath%\delsub3264.ins")
	comment "Start uninstall sub section"
	Sub "%ScriptPath%\delsub3264.ins"
endif
delsub3264.ins

Code: Alles auswählen

DefStringList $result$
DefStringList $result1$
DefVar $appKey$
DefVar $UninstallCommandList$
DefVar $appString$
DefVar $appKeyString$
DefVar $testName$
;DefVar $exeString$

Set $appKeyString$ = "DisplayName"
Set $appString$ = "Image Resizer Powertoy"

;Set $MsiId32$ = '{XXXXXXXX-XXXX-XXXX-XXXX-XXXXXXXXXXXX}'
;Set $UninstallProgram32$ = $InstallDir32$ + "\uninstall.exe"

;Set $MsiId64$ = '{XXXXXXXX-XXXX-XXXX-XXXX-XXXXXXXXXXXX}'
;Set $UninstallProgram64$ = $InstallDir64$ + "\uninstall.exe"

if ($INST_SystemType$ = "x86 System") 
;and ($INST_architecture$ = "system specific")) or ($INST_architecture$ = "both") or ($INST_architecture$ = "32 only")
	Message "Uninstalling " + $ProductId$ + "..."
	
	set $UninstallCommandList$ = ""	
	Set $result$ = getRegistryKeyList32("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall")
	for $app$ in $result$ do Sub_searchApp32
	if not ($UninstallCommandList$ = "")
		set $result1$ = splitString($UninstallCommandList$,"::")
		for $UninstallCommand$ in $result1$ do Winbatch_uninstall_32 /32Bit
		sub_check_exitcode
	endif

;	if FileExists($UninstallProgram32$)
;		comment "Uninstall program found, starting uninstall"
;		Winbatch_uninstall_32 /32Bit
;		sub_check_exitcode
;	endif

;	if not (GetRegistryStringValue32("[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\" + $MsiId32$ + "] DisplayName") = "")
;		comment "MSI id " + $MsiId32$ + " found in registry, starting msiexec to uninstall"
;		Winbatch_uninstall_msi_32
;		sub_check_exitcode
;	endif
	
	comment "Delete files"
	Files_uninstall_32 /32Bit
	Files_uninstall_AllProfiles /AllNtUserProfiles	
	comment "Cleanup registry"
	Registry_uninstall /32Bit
	Registry_uninstall_AllProfiles /AllNTUserDats
endif

if ($INST_SystemType$ = "64 Bit System") 
;and (($INST_architecture$ = "system specific") or ($INST_architecture$ = "both") or ($INST_architecture$ = "64 only"))
	Message "Uninstalling " + $ProductId$ + "..."
	
	set $UninstallCommandList$ = ""
	Set $result$ = getRegistryKeyList64("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall")
	for $app$ in $result$ do Sub_searchApp64
 	if not ($UninstallCommandList$ = "")
		set $result1$ = splitString($UninstallCommandList$,"::")
		for $UninstallCommand$ in $result1$ do Winbatch_uninstall_64 /64Bit
		sub_check_exitcode
	endif

	set $UninstallCommandList$ = ""
	Set $result$ = getRegistryKeyList32("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall")
	for $app$ in $result$ do Sub_searchApp32
	if not ($UninstallCommandList$ = "")
		set $result1$ = splitString($UninstallCommandList$,"::")
		for $UninstallCommand$ in $result1$ do Winbatch_uninstall_32 /32Bit
		sub_check_exitcode
	endif

;	if FileExists($UninstallProgram64$)
;		comment "Uninstall program found, starting uninstall"
;		Winbatch_uninstall_64 /64Bit
;		sub_check_exitcode
;	endif

;	if FileExists($UninstallProgram32$)
;		comment "Uninstall program found, starting uninstall"
;		Winbatch_uninstall_32 /64Bit
;		sub_check_exitcode
;	endif

;	if not (GetRegistryStringValue64("[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\" + $MsiId64$ + "] DisplayName") = "")
;		comment "MSI id " + $MsiId64$ + " found in registry, starting msiexec to uninstall"
;		Winbatch_uninstall_msi_64
;		sub_check_exitcode
;	endif
	
	comment "Delete files"
	Files_uninstall_64 /64Bit
	Files_uninstall_AllProfiles /AllNtUserProfiles	
	comment "Cleanup registry"
	Registry_uninstall /64Bit
	Registry_uninstall_AllProfiles /AllNTUserDats
endif

comment "Delete program shortcuts"
LinkFolder_uninstall

[Winbatch_uninstall_32]
$UninstallCommand$

[Winbatch_uninstall_64]
$UninstallCommand$

[Files_uninstall_32]
; Example for recursively deleting the installation directory (don't forget the trailing backslash):
;
; delete -sf "$InstallDir32$\"

[Files_uninstall_64]
; Example for recursively deleting the installation directory (don't forget the trailing backslash):
;
; delete -sf "$InstallDir64$\"

[Files_uninstall_AllProfiles]
; delete -sf "%UserProfileDir%\Application Data\$ProductId$\"

[Registry_uninstall]
; Example of deleting a registry key:
;
; deletekey [HKEY_LOCAL_MACHINE\Software\$ProductId$]

[Registry_uninstall_AllProfiles]


[LinkFolder_uninstall]
; Example of deleting a folder from AllUsers startmenu:
;
; set_basefolder common_programs
; delete_subfolder $ProductId$
;
; Example of deleting a shortcut from AllUsers desktop:
;
; set_basefolder common_desktopdirectory
; set_subfolder ""
; delete_element $ProductId$

[Sub_check_exitcode]
comment "Test for installation success via exit code"
set $ExitCode$ = getLastExitCode
; informations to exit codes see
; http://msdn.microsoft.com/en-us/library/aa372835(VS.85).aspx
; http://msdn.microsoft.com/en-us/library/aa368542.aspx
if ($ExitCode$ = "0")
	comment "Looks good: setup program gives exitcode zero"
else
	comment "Setup program gives a exitcode unequal zero: " + $ExitCode$
	if ($ExitCode$ = "1605")
		comment "ERROR_UNKNOWN_PRODUCT	1605	This action is only valid for products that are currently installed."
		comment "Uninstall of a not installed product failed - no problem"
	else
		if ($ExitCode$ = "1641")
			comment "looks good: setup program gives exitcode 1641"
			comment "ERROR_SUCCESS_REBOOT_INITIATED	1641	The installer has initiated a restart. This message is indicative of a success."
		else
			if ($ExitCode$ = "3010")
				comment "looks good: setup program gives exitcode 3010"
				comment "ERROR_SUCCESS_REBOOT_REQUIRED	3010	A restart is required to complete the install. This message is indicative of a success."
			else
				logError "Fatal: Setup program gives an unknown exitcode unequal zero: " + $ExitCode$
				isFatalError
			endif
		endif
	endif
endif

[Sub_searchApp32]
set $appKey$ = "[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\" + "$app$" + "] " + $appKeyString$
Set $testName$ = GetRegistryStringValue32($appKey$)
if contains($testName$,$appString$)
;	set $appKey$ = "[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\" + "$app$" + "] UninstallString"
;	Set $testName$ = GetRegistryStringValue32($appKey$)
	;if contains(lower($testName$),lower("MsiExec.exe"))
	set $UninstallCommandList$ = $UninstallCommandList$ + '"%SystemRoot%\system32\msiexec.exe" /x ' + '"$app$"' + ' /qb-! REBOOT=ReallySuppress::'
	;else
	;	Set $testName$ = unquote($testName$,'"')
	;	Set $testName$ = unquote($testName$,"'")
	;	Set $exeString$ = takeString(0, splitString ($testName$, "exe"))
	;	set $UninstallCommandList$ = $UninstallCommandList$ + $exeString$ + "exe /S::"
	;endif
endif
 
[Sub_searchApp64]
set $appKey$ = "[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\" + "$app$" + "] " + $appKeyString$
Set $testName$ = GetRegistryStringValue64($appKey$)
if contains($testName$,$appString$)
;	set $appKey$ = "[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\" + "$app$" + "] UninstallString"
;	Set $testName$ = GetRegistryStringValue64($appKey$)
	;if contains(lower($testName$),lower("MsiExec.exe"))
	set $UninstallCommandList$ = $UninstallCommandList$ + '"%SystemRoot%\system32\msiexec.exe" /x ' + '"$app$"' + ' /qb-! REBOOT=ReallySuppress::'
	;else
	;	Set $testName$ = unquote($testName$,'"')
	;	Set $testName$ = unquote($testName$,"'")
	;	Set $exeString$ = takeString(0, splitString ($testName$, "exe"))
	;	set $UninstallCommandList$ = $UninstallCommandList$ + '"' + $exeString$ + 'exe /S"::'
	;endif
endif
setup3264.ins

Code: Alles auswählen

[Actions]
;SetLogLevel=9
requiredWinstVersion >= "4.10.8.6"

;DefVar $MsiId32$
;DefVar $UninstallProgram32$
;DefVar $MsiId64$
;DefVar $UninstallProgram64$
DefVar $LogDir$
DefVar $ProductId$  
DefVar $MinimumSpace$
;DefVar $InstallDir32$
;DefVar $InstallDir64$
DefVar $ExitCode$
DefVar $INST_SystemType$
;DefVar $INST_architecture$
DefVar $INST_MsVersion$

set $INST_MsVersion$ = GetMsVersionInfo
Set $INST_SystemType$ = GetSystemType
;set $INST_architecture$ = GetProductProperty("install_architecture","system specific")
Set $LogDir$ = "%SystemDrive%\tmp"

; ----------------------------------------------------------------
; - Please edit the following values                             -
; ----------------------------------------------------------------
;$ProductId$ should be the name of the product in opsi
; therefore please: only lower letters, no umlauts, 
; no white space use '-' as a seperator
Set $ProductId$       = "imageresizer"
Set $MinimumSpace$    = "500 MB"
; the path were we find the product after the installation
;Set $InstallDir32$      = "%ProgramFiles32Dir%\<path to the product>"
;Set $InstallDir64$      = "%ProgramFiles64Dir%\<path to the product>"
; ----------------------------------------------------------------

if not(HasMinimumSpace ("%SystemDrive%", $MinimumSpace$))
	LogError "Not enough space on %SystemDrive%, " + $MinimumSpace$ + " on drive %SystemDrive% needed for " + $ProductId$
	isFatalError
	; Stop process and set installation status to failed
endif
if $INST_MsVersion$ < "5.1"
	LogError "Windows XP or newer is required for " + $ProductId$  
	isFatalError
endif
	
comment "Show product picture"
ShowBitmap "%ScriptPath%\" + $ProductId$ + ".png" $ProductId$

if FileExists("%ScriptPath%\delsub3264.ins")
	comment "Start uninstall sub section"
	Sub "%ScriptPath%\delsub3264.ins"
endif
	
comment "installing"

if ($INST_SystemType$ = "x86 System") 
;and ($INST_architecture$ = "system specific")) or ($INST_architecture$ = "both") or ($INST_architecture$ = "32 only")
	Message "Installing " + $ProductId$ + "..."
	comment "Start setup program"
	Winbatch_install_32 /32Bit
	Sub_check_exitcode
	comment "Copy files"
	Files_install_32 /32Bit
	Files_install_AllProfiles /AllNtUserProfiles
	comment "Patch Registry"
	Registry_install /32Bit
	Registry_install_AllProfiles /AllNTUserDats
	comment "Create shortcuts"
	LinkFolder_install
endif

if ($INST_SystemType$ = "64 Bit System") 
;and (($INST_architecture$ = "system specific") or ($INST_architecture$ = "both") or ($INST_architecture$ = "64 only"))
	Message "Installing " + $ProductId$ + "..."
	comment "Start setup program"
	Winbatch_install_64 /64Bit
	Sub_check_exitcode
	comment "Copy files"
	Files_install_64 /64Bit
	Files_install_AllProfiles /AllNtUserProfiles
	comment "Patch Registry"
	Registry_install /64Bit
	Registry_install_AllProfiles /AllNTUserDats
	comment "Create shortcuts"
	LinkFolder_install
endif
	

[Winbatch_install_32]
"%SystemRoot%\system32\msiexec.exe" /qb-! /l*v "$LogDir$\$ProductId$-setup.log" /package "%ScriptPath%\files\Setup32.msi" REBOOT=ReallySuppress

[Winbatch_install_64]
"%SystemRoot%\system32\msiexec.exe" /qb-! /l*v "$LogDir$\$ProductId$-setup.log" /package "%ScriptPath%\files\Setup64.msi" REBOOT=ReallySuppress ADDLOCAL=ALL REMOVE=ImageResizerFeature

[Files_install_32]
; Example of recursively copying some files into the installation directory:
;
; copy -s "%ScriptPath%\files\*.*" "$InstallDir32$"

[Files_install_64]
; Example of recursively copying some files into the installation directory:
;
; copy -s "%ScriptPath%\files\*.*" "$InstallDir64$"

[Files_install_AllProfiles]
; Example of recursively copying some files into each user profile directory:
;
; copy -s "%ScriptPath%\files\*.*" "%UserProfileDir%"

[Registry_install]
; Example of setting some values of an registry key:
;
; openkey [HKEY_LOCAL_MACHINE\Software\$ProductId$]
; set "name1" = "some string value"
; set "name2" = REG_DWORD:0001
; set "name3" = REG_BINARY:00 af 99 cd

[Registry_install_AllProfiles]
; Remove stored start menu order
deletekey [HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\MenuOrder\Start Menu]

[LinkFolder_install]
; Example of deleting a folder from AllUsers startmenu:
;
; set_basefolder common_programs
; delete_subfolder $ProductId$
;
; Example of creating an shortcut to the installed exe in AllUsers startmenu:
;
; set_basefolder common_programs
; set_subfolder $ProductId$
;
; set_link
; 	name: $ProductId$
; 	target: <path to the program>
; 	parameters:
; 	working_dir: $InstallDir$
; 	icon_file:
; 	icon_index:
; end_link
;
; Example of creating an shortcut to the installed exe on AllUsers desktop:
;
; set_basefolder common_desktopdirectory
; set_subfolder ""
;
; set_link
; 	name: $ProductId$
; 	target: <path to the program>
; 	parameters: <some_param>
; 	working_dir: $InstallDir$
; 	icon_file: <path to icon file>
; 	icon_index: 2
; end_link


[Sub_check_exitcode]
comment "Test for installation success via exit code"
set $ExitCode$ = getLastExitCode
; informations to exit codes see
; http://msdn.microsoft.com/en-us/library/aa372835(VS.85).aspx
; http://msdn.microsoft.com/en-us/library/aa368542.aspx
if ($ExitCode$ = "0")
	comment "Looks good: setup program gives exitcode zero"
else
	comment "Setup program gives a exitcode unequal zero: " + $ExitCode$
	if ($ExitCode$ = "1605")
		comment "ERROR_UNKNOWN_PRODUCT	1605	This action is only valid for products that are currently installed."
		comment "Uninstall of a not installed product failed - no problem"
	else
		if ($ExitCode$ = "1641")
			comment "looks good: setup program gives exitcode 1641"
			comment "ERROR_SUCCESS_REBOOT_INITIATED	1641	The installer has initiated a restart. This message is indicative of a success."
		else
			if ($ExitCode$ = "3010")
				comment "looks good: setup program gives exitcode 3010"
				comment "ERROR_SUCCESS_REBOOT_REQUIRED	3010	A restart is required to complete the install. This message is indicative of a success."
			else
				logError "Fatal: Setup program gives an unknown exitcode unequal zero: " + $ExitCode$
				isFatalError
			endif
		endif
	endif
endif
I renamed the downloaded files, because with a versionnumber you would have to edit the script with every new version.

Anyway, I think your msi uninstall command was somehow not working correctly. Or it's because you might have installed the 64-bit version without looking for the key in the 64-bit portion of the registry.
Bitte schreiben Sie Deutsch, when I'm responding in the German-speaking part of the forum!
cyberfrk
Beiträge: 15
Registriert: 03 Mai 2013, 23:10

Re: Impossible to uninstall imageresizer (msi)?

Beitrag von cyberfrk »

Hi,

Your files work perfectly but, yes...there is a "but", I've got another problem...Can you try to install the product, try to resize (right click on 1 picture and "Resize Pictures") and uninstall the product. After uninstalling, on screen, I only see the wallpaper and the mouse. No other things to the screen. I must close the session and open it... The same in 32&64 bits.
*snif*
Benutzeravatar
SisterOfMercy
Beiträge: 1522
Registriert: 22 Jun 2012, 19:18

Re: Impossible to uninstall imageresizer (msi)?

Beitrag von SisterOfMercy »

cyberfrk hat geschrieben:After uninstalling, on screen, I only see the wallpaper and the mouse. No other things to the screen. I must close the session and open it... The same in 32&64 bits.
No problems here. I don't know, you might want to share the logfile, but I'm afraid that will probably only show a successfull uninstall. Maybe someone else has any idea?
Bitte schreiben Sie Deutsch, when I'm responding in the German-speaking part of the forum!
Antworten